Question

I wrote a perl script to count the occurrences of a character in a file.
So far this is what I have got,

#!/usr/bin/perl -w

use warnings;
no warnings ('uninitialized', 'substr');

my $lines_ref;
my @lines;
my $count;

sub countModule()
{
my $file = "/test";
open my $fh, "<",$file or die "could not open $file: $!";
my @contents = $fh;
my @filtered = grep (/\// ,@contents);
return \@filtered;
}

@lines = countModule();
#@lines = $lines_ref;
$count = @lines;
print "###########\n $count \n###########\n";

My test file looks like this:

10.0.0.1/24
192.168.10.0/24
172.16.30.1/24

I am basically trying to count the number of instances of “/”

This is the output that I get:

###########
 1
###########

I am getting 1 instead of 3, which is the number of occurrences.
Still learning perl, so any help will be appreciated..Thank you!!

Answer 1

Close, but a few issues:

use strict;
use warnings;

sub countModule
{
    my $file = "/test";
    open my $fh, "<",$file or die "could not open $file: $!";
    my @contents = <$fh>;  # The <> brackets are used to read from $fh.
    my @filtered = grep (/\// ,@contents);
    return @filtered;      # Remove the reference.
}

my @lines = countModule();
my $count = scalar @lines;  # 'scalar' is not required, but lends clarity.
print "###########\n $count \n###########\n";

Each of the changes I made to your code are annotated with a #comment explaining what was done.

Now in list context your subroutine will return the filtered lines. In scalar context it will return a count of how many lines were filtered.

You did also mention find the occurrences of a character (despite everything in your script being line-oriented). Perhaps your counter sub would look like this:

sub file_tallies{
    my $file = '/test';
    open my $fh, '<', $file or die $!;
    my $count;
    my $lines;
    while( <$fh> ) {
        $lines++;
        $count += $_ =~ tr[\/][\/];
    }
    return ( $lines, $count );
}

my( $line_count, $slash_count ) = file_tallies();