Question

I’d like to check on every call to my object’s methods some value (in this case: token’s age). Is it possible to set it to all methods at once? Like in constructor? I have such simple constructor:

sub new {
    my $class = shift;
    my %args = @_;
    my $self  = {};

    $self->{key} = $args{key};
    bless($self, $class);

    ($self->{token}, $self->{token_start}) = $self->_get_authorized_token(); 
    return $self;
}

And bunch of methods, which depends of tokens age, like this:

sub add_item {
    my $self = shift;
    my %args = @_;
    ...
}

I’d like to avoid including age-checking in every method, so i look for more general way to implement it. Has there some?

Answer 1

All I can think of is to hide all your ‘real’ methods – either in the classical way with a preceding underscore, or in a hash of subroutines – and use AUTOLOAD to direct the call properly.

The example below shos the idea

module MyClass.pm

package MyClass;

use strict;
use warnings;

sub new {
  bless {}, __PACKAGE__;
}

sub _method1 {
  print "In method1\n";
}

sub _method2 {
  print "In method2\n";
}

sub AUTOLOAD {

  our $AUTOLOAD;

  my ($class, $method) = $AUTOLOAD =~ /(.+)::(.+)/;
  return if $method eq 'DESTROY';

  my $newmethod = "${class}::_$method";
  unless (exists &$newmethod) {
    die qq(Can't locate object method "$method" via package "$class");
  }

  print "Preprocessing...\n";
  goto &$newmethod 
}

1;

program

use strict;
use warnings;

use MyClass;

my $thing = MyClass->new;

$thing->method1;
$thing->method2;
$thing->method3;

output

Preprocessing...
In method1
Preprocessing...
In method2
Can't locate object method "method3" via package "MyClass" at MyClass.pm line 23.