Question

If I have the following code

sub a {
    my $id = shift;
    # does something
    print &a_section($texta);
    print &a_section($textb);
    sub a_section {
        my $text = shift;
        # combines the $id and the $text to create and return some result.
    }
}

Assuming a_section is called only by a, will I run into a memory leak, variable dependability, or other problem?

I am exploring this as an alternative so I can avoid the necessity of passing $id to a_section.

Answer 1

First, it’s not a private sub. It’s fully visible from the outside. Two, you will have problems.

$ perl -wE'
   sub outer {
      my ($x) = @_;
      sub inner { say $x; }
      inner();
   }
   outer(123);
   outer(456);
'
Variable "$x" will not stay shared at -e line 4.
123
123     <--- XXX Not 456!!!!

You could do:

sub a {
    my $id = shift;

    local *a_section = sub {
        my $text = shift;
        # combines the $id and the $text to create and return some result.
    };

    print a_section($texta);
    print a_section($textb);
}

(You can call the inner sub recursively using a_section(...).)

or:

sub a {
    my $id = shift;

    my $a_section = sub {
        my $text = shift;
        # combines the $id and the $text to create and return some result.
    };

    print $a_section->($texta);
    print $a_section->($textb);
}

(Use __SUB__->(...) if you want to call the inner sub recursively to avoid memory leak, available in Perl 5.16+.)