Question

If I were to have the following XML document…

<?xml version="1.0"?>
<document>
  <title>Foobar</title>
  <article>
    Phasellus ultrices arcu suscipit velit laoreet eu dignissim 
    dolor pulvinar. Proin ac libero a diam laoreet iaculis nec eu risus.

    <ref url="http://en.wikipedia.org/wiki/FooBar">Foobar</ref> potenti. 
    Duis placerat laoreet est nec fringilla. Quisque vitae semper erat.
  </article>
</document>

…how would I translate the article element to the following?

<p>
  Phasellus ultrices arcu suscipit velit laoreet eu dignissim 
  dolor pulvinar. Proin ac libero a diam laoreet iaculis nec eu risus.

  <a href="http://en.wikipedia.org/wiki/FooBar">Foobar</a> potenti. 
  Duis placerat laoreet est nec fringilla. Quisque vitae semper erat.
</p>

Specifically, it’s the ref to a translation I’m interested in, since it’s embedded within a block of plain text.

Answer 1

If you build upon the standard XSTL Identity Transform, this is a straight-forward task, you just need a template to match a ref element and output an a element instead.

<xsl:template match="ref">
   <a>
      <xsl:apply-templates select="@*|node()"/>
   </a>
</xsl:template>

And to replace the attribute, you then have another template

<xsl:template match="ref/@url">
   <xsl:attribute name="href">
      <xsl:value-of select="." />
   </xsl:attribute>
</xsl:template>

Note that if your ref element was guaranteed to always have an url attribute, you could also simplify those two templates into just one, like this:

<xsl:template match="ref">
   <a href="{@url}">
      <xsl:apply-templates select="node()"/>
   </a>
</xsl:template>

You would then add other templates to replace any other elements as required, such as article being changed to p, and also a template to not output the title element.

Here is the full XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/document">
         <xsl:apply-templates />
   </xsl:template>

   <xsl:template match="title" />

   <xsl:template match="article">
      <p>
         <xsl:apply-templates />
      </p>
   </xsl:template>

   <xsl:template match="ref">
      <a>
         <xsl:apply-templates select="@*|node()"/>
      </a>
   </xsl:template>

   <xsl:template match="ref/@url">
      <xsl:attribute name="href">
         <xsl:value-of select="." />
      </xsl:attribute>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

When applied to your sample XML, the following is output

<p>
    Phasellus ultrices arcu suscipit velit laoreet eu dignissim 
    dolor pulvinar. Proin ac libero a diam laoreet iaculis nec eu risus.

    <a href="http://en.wikipedia.org/wiki/FooBar">Foobar</a> potenti. 
    Duis placerat laoreet est nec fringilla. Quisque vitae semper erat.
  </p>