Question

If today is say 15th August 2012 then the query should return the following

15/01/2011,
15/02/2011,
...
...
15/07/2012
15/08/2012

If today is 31st August 2012 then the query would return

31/01/2011,
28/02/2011,  <<<<this is the nearest date
...
...
31/07/2012
31/08/2012

We have a vw_DimDate in our Warehouse which should help

edit
It contains the following fields

Currently I’m using the following but it seems rather convoluted! …

DECLARE @Dt DATETIME = '31 JUL 2012'--GETDATE()

;WITH DateSet_cte(DayMarker)
        AS
        (
        SELECT DayMarker
        FROM WHData.dbo.vw_DimDate
        WHERE 
                DayMarker >= CONVERT(DATETIME,CONVERT(CHAR(4),DATEADD(YEAR,-1,@Dt),112) + '0101') AND
                DayMarker <=@Dt
        )
, MaxDate_cte(MaxDate)
        AS
        (
        SELECT [MaxDate] = MAX(DayMarker)
        FROM DateSet_cte 
        )       
SELECT
            [Mth] = CONVERT(DATETIME,CONVERT(CHAR(6),a.DayMarker,112) + '01')
            , MAX(a.DayMarker) [EquivDate]
FROM DateSet_cte a
WHERE DAY(a.DayMarker) <= (SELECT DAY([MaxDate]) FROM MaxDate_cte)
GROUP BY CONVERT(DATETIME,CONVERT(CHAR(6),a.DayMarker,112) + '01')

Answer 1

;with Numbers as (
    select distinct number from master..spt_values where number between 0 and 23
), Today as (
    select CONVERT(date,CURRENT_TIMESTAMP) as d
)
select
    DATEADD(month,-number,d)
from
    Numbers,Today
where DATEPART(year,DATEADD(month,-number,d)) >= DATEPART(year,d) - 1

Seems odd to want a variable number of returned values based on how far through the year we are, but that’s what I’ve implemented.

When you use DATEADD to add months to a value, then it automatically adjusts the day number if it would have produced an out of range date (e.g. 31st February), such that it’s the last day of the month. Or, as the documentation puts it:

If datepart is month and the date month has more days than the return month and the date day does not exist in the return month, the last day of the return month is returned.

Of course, if you already have a numbers table in your database, you can eliminate the first CTE. You mentioned that you “have a vw_DimDate in our Warehouse which should help”, but since I have no idea on what that (presumably, a) view contains, it wasn’t any help.