Question

I’m a big fan of functional programming, so when I discovered block references in Perl I started using them a lot.

However, the functions I’ve written that take blocks as arguments are written in this style:

sub mygrep (&@) {
    my $code = shift;
    my @result;
    foreach $_ (@_) {
        push(@result, $_) if &$code;
    }
    @result;
}

(From http://perldoc.perl.org/perlsub.html#Prototypes)

In essence, most of my functions set $_ in order for the code block to gain access to data in my sub. I guess my question can be split into three subquestions:

1. Are there some major pitfalls in this approach?
2. Is it a better idea to localize $_ before setting it?
3. Should i use partially applied functions instead?

I’m still a Perl newbie so any answers and suggestions are appreciated – thanks in advance! 🙂

Answer 1

1. Are there some major pitfalls in this approach?

1. my $_; in view of the block will hide your changes to package variable $_. There’s nothing you can do about that from inside of mygrep.

2. &$code is very special. You want &$code() or $code->() instead.

3. Changing $_ will change the arguments passed to mygrep. That’s undesirable here.

2. Is it a better idea to localize $_ before setting it?

for provides much better localisation that local, but it also provides aliasing that’s undesirable here.

3. Should i use partially applied functions instead?

I don’t know what that means.

---

Fixed:

sub mygrep (&@) {
    my $code = shift;
    my @result;
    for (@_) {
       # Create copy so $_ can be modified safely.
       for (my $s = $_) {
          push @result, $_ if $code->();
       }
    }

    return @result;
}

---

That said, I think mygrep is kind pointless, since map+grep already does what you want more easily. Compare

mygrep { if ($_ % 2) { ++$_; 1 } else { 0 } } LIST

with

map { $_+1 } grep { $_ % 2 } LIST

You can even merge the map and grep.

map { $_ % 2 ? $_+1 : () } LIST