Question

I’m all new to this treeview business. I have a fixed treeview, very simple and basic. Only two levels, parent and child nodes. I just need two things out of this treeview.

1) If parent is checked, check all child nodes.

2) If just one child node is unchecked, uncheck parent node.

That’s it! I’ve been looking for this for 30 mins and I cant find it. Maybe because my vb.net is old, it doesnt seem to be the same as others =/ I’m using vb.net 2003. Thank you very much 😀

Answer 1

Working example in VB.Net 2008, but it should work in 2003:

Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
  For i As Integer = 1 To 3
    Dim node As New TreeNode("Parent #" & i.ToString)
    node.Nodes.Add("Child #1")
    node.Nodes.Add("Child #2")
    node.Expand()

    TreeView1.Nodes.Add(node)
  Next
End Sub

Private Sub TreeView1_AfterCheck(ByVal sender As Object, ByVal e As TreeViewEventArgs) Handles TreeView1.AfterCheck
  RemoveHandler TreeView1.AfterCheck, AddressOf TreeView1_AfterCheck

  For Each node As TreeNode In e.Node.Nodes
    node.Checked = e.Node.Checked
  Next

  If e.Node.Checked Then
    If e.Node.Parent Is Nothing = False Then
      Dim allChecked As Boolean = True

      For Each node As TreeNode In e.Node.Parent.Nodes
        If Not node.Checked Then
          allChecked = False
        End If
      Next

      If allChecked Then
        e.Node.Parent.Checked = True
      End If

    End If
  Else
    If e.Node.Parent Is Nothing = False Then
      e.Node.Parent.Checked = False
    End If
  End If

  AddHandler TreeView1.AfterCheck, AddressOf TreeView1_AfterCheck
End Sub