Question

I’m attached to a network drive with a ridiculously slow connection speed (15 kb/s on good days). I’m deleting most files but don’t want to break a few files that have include statements. These are files for an enterprise app (mainly written in ColdFusion). My idea is to prefix a ‘_’ to all file names as to test if the few files I want to keep get messed up. I already searched the code of files I want to keep for include statements, this is just to test before pushing live.

Is there a script I can run that would rename all files and folders but exclude 2 folders and the files in them? If there’s a better way I’m open to options.

So I’d normally delete all files I think aren’t needed, but since the network speed is terrible that would take a long time. Since this is testing if I make a mistake there could be a lot of deleting and undeleting, that’s why I want to just rename.

Answer 1

I suggest appending an extension of ._ instead of prefixing the name with _. That will make it easier to undo the rename.

@echo off
setlocal
set root="X:\"
set skip1="X:\folder1\"
set skip2="X:\folder2\"
for /r %root% %%F in (*) do (
  if /i "%%~dpF" neq %skip1% if /i "%%~dpF" neq %skip2% ren "%%F" "%%~nxF._"
)

To revert back to the original names:

@echo off
setlocal
set root="X:\"
for /r %root% %%F in (*._) do ren "%%F" "%%~nF"

EDIT:
The first script to rename the files can be made faster by renaming all files in a directory with a single REN command.

@echo off
setlocal
set root="X:\"
set skip1="X:\folder1\"
set skip2="X:\folder2\"
for /r %root% %%F in (.) do (
  if /i "%%~fF" neq %skip1% if /i "%%~fF" neq %skip2% ren "%%~F\*.*" *.*._
)

The second script to revert the names must continue to rename each file individually.

I also added SETLOCAL to all scripts.