Question

I’m attempting to send an image and some text to a server at the same time.

I’m using WebRequest like the following to send text:

Dim ba As Byte() = Encoding.UTF8.GetBytes(query)

Dim wr As WebRequest = WebRequest.Create(Me.server_url)
wr.Method = "POST"
wr.ContentType = "application/x-www-form-urlencoded"
wr.ContentLength = ba.Length

And I have the following using WebClient for sending an image:

System.Net.WebClient Client = new System.Net.WebClient();

Client.Headers.Add("Content-Type", "binary/octet-stream");

byte[] result = Client.UploadFile(Properties.Settings.Default.script_url, 
"POST", "desktop.png");

But I cannot figure out how to do both at the same time.

Answer 1

After lots of searching, I found the following link:

http://www.paraesthesia.com/archive/2009/12/16/posting-multipartform-data-using-.net-webrequest.aspx

It is for C#, so here is a proof of concept I put together for VB:

Dim boundry As String = "---------------------------" + DateTime.Now.Ticks.ToString("x")
    Dim request As WebRequest = WebRequest.Create(Globals.script_path + "uploader.php")
    request.Method = "POST"
    request.ContentType = "multipart/form-data; boundary=" + boundry

    Dim requestStream As Stream = request.GetRequestStream()

    '' send text data
    Dim data As Hashtable = New Hashtable()
    data.Add("text_input", "Hello World")

    For Each key As String In data.Keys
        Dim item As String = "--" + boundry + vbCrLf + "Content-Disposition: form-data; name=""" & key & """" + vbCrLf + vbCrLf + data.Item(key) + vbCrLf
        Dim itemBytes() As Byte = System.Text.Encoding.UTF8.GetBytes(item)
        requestStream.Write(itemBytes, 0, itemBytes.Length)

    Next

    '' send image data
    Dim file_header = "--" + boundry + vbCrLf + "Content-Disposition: form-data; name=""file_1"";filename=""file.png""" + vbCrLf + "Content-Type: image/png" + vbCrLf + vbCrLf
    Dim file_header_bytes() As Byte = System.Text.Encoding.UTF8.GetBytes(file_header)
    requestStream.Write(file_header_bytes, 0, file_header_bytes.Length)
    Dim ms As MemoryStream = New MemoryStream()
    timecard.screen_shot.Save(ms, ImageFormat.Png)
    Dim file_bytes() As Byte = ms.GetBuffer()
    ms.Close()
    requestStream.Write(file_bytes, 0, file_bytes.Length)
    Dim file_footer_bytes() As Byte = System.Text.Encoding.UTF8.GetBytes(vbCrLf)
    requestStream.Write(file_footer_bytes, 0, file_footer_bytes.Length)


    '' send
    Dim endBytes() As Byte = System.Text.Encoding.UTF8.GetBytes("--" + boundry + "--")
    requestStream.Write(endBytes, 0, endBytes.Length)
    requestStream.Close()



    Dim response As WebResponse = request.GetResponse()
    Dim reader As StreamReader = New StreamReader(response.GetResponseStream())
    Debug.WriteLine(reader.ReadToEnd())

This, of course, is geared toward my personal needs, but I think it describes well what needs to be done. For the image, there is a filename. In this case, it is not an actual file. But the PHP receiving the file needs the data.

Here is the PHP code I used to test this:

<?php
if (isset($_POST['text_input'])){
echo $_POST['text_input'];
    $target_path = "screenshots/";

    $target_path = $target_path . basename( $_FILES['file_1']['name']); 

    if(move_uploaded_file($_FILES['file_1']['tmp_name'], $target_path)) {
        echo "The file ".  basename( $_FILES['file_1']['name']). 
        " has been uploaded";
    } else{
        echo "There was an error uploading the file, please try again!";
    }
}else{
    echo "no dta";
}

?>

take care,
lee