Question

I’m attempting to transform this data:

ItemID  MonthAsInt  Month     Year  InvType     Quantity
4643    4           April     2011  Shipment    10
4643    5           May       2011  Shipment    10
4643    7           July      2011  Shipment    10
4643    8           August    2011  Destroy     10
4643    11          November  2011  Shipment    25
4643    12          December  2011  Picking     1

Into this (basically, a 12 month snap shot):

              February    March    April     May    June    July    August    ...

Shipment      0           0        10        10     0       10      0
Picking       0           0        0         0      0       0       0
Destroy       ...

I’ve messed with the PIVIOT method, but I haven’t had much luck. At this point, all I have is the list of dates that I need between GETDATE() and GETDATE() - 12 months (retrieved with the query below):

DECLARE @BeginDate DATETIME
DECLARE @EndDate DATETIME

SET @BeginDate = GETDATE();
SET @EndDate = DATEADD(MONTH, -12, GETDATE());

WITH CTE_DatesTable
AS
(
    SELECT @EndDate AS [Date]

    UNION ALL

    SELECT  DATEADD(dd, 1, [date])
    FROM    CTE_DatesTable
    WHERE   DATEADD(dd, 1, [date]) <= @BeginDate
)

SELECT DISTINCT DATENAME(MONTH, [date]) + ' ' 
        + CAST(YEAR([date]) AS VARCHAR(4)) AS MonthYear,
                YEAR([date]) AS YearAsInt,
                MONTH([Date]) AS MonthAsInt
FROM            CTE_DatesTable
ORDER BY        YEAR([date]), MONTH([Date])
OPTION          (MAXRECURSION 0)

See the query in action here.

Is what I’m trying to accomplish possible? Am I going in the right direction? Any help would be appreciated!

Answer 1

You can do this without pivot (the syntax for which I find daunting as well). Since you don’t know the actual layout of columns beforehand, I think this is easiest with dynamic SQL. Given the following table/sample data:

USE tempdb;
GO

CREATE TABLE dbo.foo
(
    ItemID INT, 
    MonthAsInt INT, 
    [Month] VARCHAR(12), 
    [Year] INT, 
    InvType VARCHAR(12), 
    Quantity INT
);

INSERT dbo.foo SELECT 4643,4 ,'April   ',2011,'Shipment',10
UNION ALL SELECT 4643,5 ,'May     ',2011,'Shipment',10
UNION ALL SELECT 4643,7 ,'July    ',2011,'Shipment',10
UNION ALL SELECT 4643,8 ,'August  ',2011,'Destroy ',10
UNION ALL SELECT 4643,11,'November',2011,'Shipment',25
UNION ALL SELECT 4643,12,'December',2011,'Picking ',1;

You can generate a list of months using a much simpler CTE, and build a dynamic SQL statement based off of that:

DECLARE @sql NVARCHAR(MAX) = N'';

;WITH n AS 
(
    SELECT TOP (12) d = DATEADD
    (
        MONTH, 
        -(ROW_NUMBER() OVER (ORDER BY [object_id]) - 1), 
        GETDATE()
    )
    FROM sys.objects
    ORDER BY d DESC
)
SELECT @sql = @sql + N',' + CHAR(13) + CHAR(10) + DATENAME(MONTH, d) 
    + ' = SUM(CASE WHEN [Year] = ' + CONVERT(VARCHAR(4), DATEPART(YEAR, d))
    + ' AND MonthAsInt = ' + CONVERT(VARCHAR(2), DATEPART(MONTH, d)) 
    + ' THEN Quantity ELSE 0 END)'
FROM n
ORDER BY d;

SELECT @sql = N'SELECT InvType' + @sql + '
    FROM dbo.foo
    GROUP BY InvType';

PRINT @sql;
-- EXEC sp_executesql @sql;

I put the PRINT there so you could test it out before running it. I wasn’t sure if you needed 12 months or 13 months, you can just change the TOP (12) to TOP (13) if you want 13 months, or remove the -1 if you don’t want the current month included.