Question

I’m completely new to Flash and AS3. I’ve Googled around an cannot find anything on this topic.

I have some code that posts an image to a php file:

var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
    var jpgURLRequest:URLRequest = new URLRequest("http://127.0.0.1/gdipORG/takeImage.php");
    jpgURLRequest.requestHeaders.push(header);
    jpgURLRequest.method = URLRequestMethod.POST;
    jpgURLRequest.data = byteArray;
navigateToURL(jpgURLRequest, "blank");

Problem is, for the actual posting to take place, I have to navigate to the actual url (see last line of code)…

I want to be able to post the data to the url without having to navigate to it. Any ideas?

Answer 1

Use a URLLoader right after your existing code:

//Existing code
var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
var jpgURLRequest:URLRequest = new URLRequest("http://127.0.0.1/gdipORG/takeImage.php");
jpgURLRequest.requestHeaders.push(header);
jpgURLRequest.method = URLRequestMethod.POST;
jpgURLRequest.data = byteArray;

//KILL THIS LINE navigateToURL(jpgURLRequest, "blank");

//Add these (UNTESTED CODE):

var sendJPGLoader:URLLoader = new URLLoader();
sendJPGLoader.dataFormat = URLLoaderDataFormat.BINARY;
sendJPGLoader.addEventListener(Event.COMPLETE, sendJPGToServerComplete);
sendJPGLoader.addEventListener(IOErrorEvent.IO_ERROR, sendJPGToServerIOError);

//Try to send image
sendJPGLoader.load(jpgURLRequest); 

function sendJPGToServerComplete(evt:Event):void {
  //Request was sent to server succesfully
  //Optionally check server response
  // var serverResponse:String = String(evt.target.data);
}

function sendJPGToServerIOError(evt:Event):void {
  //Failed
}

At the top of your code don’t forget to import:

import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.net.URLLoader;
import flash.net.URLLoaderDataFormat;
import flash.net.URLRequest;
import flash.net.URLRequestMethod;

I think I got them all 🙂