Question

I’m creating a bactch file, which in turn needs to create and execute another bactch file in a second window. I’m using the “start” command, but in the new window basic commands such as timeout and ping fail as not recognised. Note that if I run start from the command line but not in a batch file there aren’t any problems, this only happens when using start inside a batch file. Any ideas please? 🙂

Btw o/s is windows 7 Pro SP1 64 bit.

— Original window —

C:\mydir>start tmp.bat

— New window —

C:\mydir>c:

C:\mydir>cd \mydir

C:\mydir>echo Please wait for 60 seconds...
Please wait for 60 seconds...

C:\mydir>timeout 60
'timeout' is not recognized as an internal or external command,
operable program or batch file.

C:\mydir>ping 127.0.0.1
'ping' is not recognized as an internal or external command,
operable program or batch file.

— Full batch file —

set drive=c:
set path=\mydir
set tmpbatch=tmp.cmd

%drive%
cd %path%
echo %drive% > %tmpbatch%
echo cd %path% >> %tmpbatch%
echo echo Please wait for 60 seconds... >> %tmpbatch%
echo timeout 60 >> %tmpbatch%
echo copy config\topology.default.txt config\topology.txt >> %tmpbatch%
echo copy config\fasrc.default config\fasrc >> %tmpbatch%
echo echo demolive2^|localhost^|3^|demo^|Live Query Instance 2 for demo setup ^>^> config\topology.txt >> %tmpbatch%
echo bin\setup-cluster >> %tmpbatch%
echo findstr ERROR data\log\agent.log data\instances\deployment\log\kitchen.log >> %tmpbatch%
echo bin\capture-import demo demo\config\demo-config-capture.zip >> %tmpbatch%
echo bin\run-etl-job run.kjb "-DINSTANCE=demo" "-DTRIGGER=load-data" >> %tmpbatch%
echo bin\reindex demo >> %tmpbatch%
echo start "~\iexplore.exe" "http://localhost:8180/preview" >> %tmpbatch%
echo echo Please publish the configuration to the servers using File ^^^> File in the Business Manager >> %tmpbatch%
echo echo Press a key to continue once you have done that... >> %tmpbatch%
echo pause >> %tmpbatch%
echo bin\reindex demo >> %tmpbatch%
echo bin\fresh-index-to-live demo >> %tmpbatch%
echo echo All done!  Check back for errors... >> %tmpbatch%
echo pause >> %tmpbatch%
echo del %tmpbatch% >> %tmpbatch%
start %tmpbatch%
bin\deployment-agent

Answer 1

It is because in your full batch file you are resetting the PATH variable which is a system environment variable. I recommend changing the name to MYPATH.