Question

I’m creating a perl script to convert a list of commands in a template file () and output them to another file in a different format in an output file ().

The commands in the template file will look as follows:

command1 --max-size=2M --type="some value"

I’m having some problems extracting the options and values from this string. So far i have:

m/(\s--\w*=)/ig

Which will return:

" --max-size="
" --type="

However I have no idea how to return both the option and value as a separate variable or how to accommodate for the use of quotes.

Could anyone steer me in the right direction?

side note: I’m aware that Getops does an awesome job at doing this from the command-line but unfortunately these commands are passed as strings 🙁

Answer 1

The code below produces

@args = ('command1', '--max-size=2M', '--type=some value');

That is suitable to pass to GetOptions as follows:

local @ARGV = @args;
GetOptions(...) or die;

Finally, the code:

for ($cmd) {
   my @args;
   while (1) {
      last if /\G \s* \z /xgc;

      /\G \s* /xgc;

      my $arg;
      while (1) {
         if (/\G ([^\\"'\s]) /xgc) {
            $arg .= $1;
         }
         elsif (/\G \\ /xgc) {
            /\G (.) /sxgc
               or die "Incomplete escape";

            $arg .= $1;
         }
         elsif (/\G (?=") /xgc) {
            /\G " ( (?:[^"\\]|\\.)* ) " /sxgc
               or die "Incomplete double-quoted arging";

            my $quoted = $1;
            $quoted =~ s/\\(.)/$1/sg;

            $arg .= $quoted;
         }
         elsif (/\G (?=') /xgc) {
            /\G ' ( [^']* ) ' /xgc
               or die "Incomplete single-quoted arging";

            $arg .= $1;
         }
         else {
            last;
         }
      }

      push @args, $arg;
   }

   @args
      or die "Blank command";

   ...
}