Question

I’m currently working on a flash game and I need to know how to addChild a BitmapData or draw a BitmapData to screen. If I can’t than how can I give a DisplayObject my BitmapData?

Answer 1

BitmapData objects cannot be added directly to the screen since they aren’t descendants of DisplayObject. If you’d like to display the contents of a BitmapData object, you’ll need to use a Bitmap, and it’s bitmapData property. If you’re using Flex, you’ll need to make sure that you’re placing the Bitmap into an instance of UIComponent or one of it’s subclasses. Otherwise, if you’re just using AS3 in Flash, this will do it:

    package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.geom.Point;

    public class BitmapDataExample extends Sprite
    {
        public function BitmapDataExample()
        {
            super();

            var canvasSize:uint = 100;
            var size:uint = 5;
            var bd:BitmapData = new BitmapData (canvasSize, canvasSize, false, 0x000000);

            var bmp:Bitmap = new Bitmap (bd);
            addChild(bmp);

            // everything from this point on is just drawing junk into the BitmapData object
            var p:Point = new Point (0, 0);
            for (var y = 0; y < canvasSize; y++)
            {
                p.y = y;

                for (var x = 0; x < canvasSize; x++)
                {
                    p.x = x;

                    if (p.x % size == p.y % size)
                        bd.setPixel(p.x, p.y, 0x00FF00);
                }
            }
        }

    }
}