Question

I’m filtering out certain nodes in my XSLT transform, and among those remaining I need to insert a element if a certain sub element is missing.

Here is what I have.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" >
<xsl:output method="xml" indent="yes"/>

  <xsl:template xpath-default-namespace="http://www.tempuri.org" match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template xpath-default-namespace="http://www.tempuri.org" match="SomeNode">
  </xsl:template>
  <xsl:template xpath-default-namespace="http://www.tempuri.org" match="TheNode[@type!='SomeType' and @type!='OtherType']">

<!-- If TheNode is missing a child element SomeElement, insert a blank SomeElement element -->

  </xsl:template>

</xsl:stylesheet>

Can someone suggest the best way of going about this please?

Thanks.

Answer 1

This transformation:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xpath-default-namespace="http://www.tempuri.org" >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="SomeNode">
  </xsl:template>
  <xsl:template match=
      "TheNode[not(@type = ('SomeType','OtherType')) and not(SomeElement)]">
    <xsl:copy>
     <xsl:apply-templates select="@*"/>
     <SomeElement xmlns="http://www.tempuri.org"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

when applied to this XML document:

<t xmlns="http://www.tempuri.org">
 <a>
  <b/>
  <SomeNode/>
  <TheNode type="x"/>
  <TheNode type="y">
   <SomeElement/>
  </TheNode>
 </a>
</t>

produces the wanted, correct result:

<t xmlns="http://www.tempuri.org">
   <a>
      <b/>
      <TheNode type="x">
         <SomeElement/>
      </TheNode>
      <TheNode type="y">
         <SomeElement/>
      </TheNode>
   </a>
</t>