Home/ Questions/Q 8118545
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-06T04:31:21+00:00

I’m having an issue implementing an excel feature I’m after, this is my data

  • 0

I’m having an issue implementing an excel feature I’m after, this is my data below. I’m trying to get it to count the amount of different users, which is depicted in the second column against the silo’s which is the last column.

175 u544835 E&T-Aero    175 comp04_899  13/06/2012  Silo 4
175 u403114 E&T-Aero    175 comp04_900  14/06/2012  Silo 4
175 u403115 E&T-Aero    175 comp04_901  15/06/2012  Silo 4
176 u403116 Fans-AE     176 comp04_902  13/06/2012  Silo 4
177 u403117 Fans-Mech   177 comp04_903  13/06/2012  Silo 4
178 u544835 CA-WEM      178 comp04_904  13/06/2012  Silo 4
179 u544835 Nacelles    179 comp04_905  13/06/2012  Silo 4
180 u544835 Nacelles    180 comp04_906  13/06/2012  Silo 4
181 u544835 E&T-Aero    181 comp04_907  15/06/2012  Silo 4
186 u544835 E&T-Aero    186 comp04_908  20/06/2012  Silo 4
187 u544835 E&T-Aero    187 comp04_909  20/06/2012  Silo 4
189 u544833 E&T-Aero    189 comp04_910  20/06/2012  Silo 4
192 u544834 E&T-Aero    192 comp04_911  20/06/2012  Silo 4
193 u544835 Comp-AD     193 comp04_912  20/06/2012  Silo 4

my efforts have given me so far :

=SUM(IF(FREQUENCY(MATCH($FF$2:$FF$15,$FF$2:$FF$15,0),MATCH($FF$2:$FF$15,$FF$2:$FF$15,0))>0,1))

this tells me how many different user’s there are in the list but not different users against Silo’s

any help would be kindly appreciated

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    If silos are in column FK then this version will give you the number of different users for silo 4

    =SUM(IF(FREQUENCY(IF($FK$2:$FK$15="silo 4",IF($FF$2:$FF$15<>"",MATCH($FF$2:$FF$15,$FF$2:$FF$15,0))),ROW($FF$2:$FF$15)-ROW($FF$2)+1),1))

    That’s an array formula that needs to be confirmed with CTRL+SHIFT+ENTER

    In Excel 2007 or later versions you could also use this version

    =SUMPRODUCT(($FK$2:$FK$15=”silo 4″)/COUNTIFS($FK$2:$FK$15,$FK$2:$FK$15&””,$FF$2:$FF$15,$FF$2:$FF$15&””))

    Note: for different users only (i.e. a replacement for your formula above) it would simpler to use this version

    =SUMPRODUCT(($FF$2:$FF$15<>"")/COUNTIF($FF$2:$FF$15,$FF$2:$FF$15&""))

    • 0