Question

I’m having trouble modifying a script that processes files passed as command line arguments, merely for copying those files, to additionally modifying those files. The following perl script worked just fine for copying files:

use strict;
use warnings;

use File::Copy;

foreach $_ (@ARGV) {
   my $orig = $_;
   (my $copy = $orig) =~ s/\.js$/_extjs4\.js/;
   copy($orig, $copy) or die(qq{failed to copy $orig -> $copy});
}

Now that I have files named “*_extjs4.js”, I would like to pass those into a script that similarly takes file names from the command line, and further processes the lines within those files. So far I am able get a file handle successfully as the following script and it’s output shows:

use strict;
use warnings;

foreach $_ (@ARGV) {
    print "$_\n";
    open(my $fh, "+>", $_) or die $!;
    print $fh;
    #while (my $line = <$fh>) {
    #    print $line;
    #}
    close $fh;
}

Which outputs (in part):

./filetree_extjs4.js
GLOB(0x1a457de8)
./async_submit_extjs4.js
GLOB(0x1a457de8)

What I really want to do though rather than printing a representation of the file handle, is to work with the contents of the files themselves. A start would be to print the files lines, which I’ve tried to do with the commented out code above.

But that code has no effect, the files’ lines do not get printed. What am I doing wrong? Is there a conflict between the $_ used to process command line arguments, and the one used to process file contents?

Answer 1

It looks like there are a couple of questions here.

---

What I really want to do though rather than printing a representation of the file handle, is to work with the contents of the files themselves.

The reason why print $fh is returning GLOB(0x1a457de8) is because the scalar $fh is a filehandle and not the contents of the file itself. To access the contents of the file itself, use <$fh>. For example:

while (my $line = <$fh>) {
    print $line;
}

# or simply print while <$fh>;

will print the contents of the entire file.

This is documented in pelrdoc perlop:

If what the angle brackets contain is a simple scalar variable (e.g.,
<$foo>), then that variable contains the name of the filehandle to
input from, or its typeglob, or a reference to the same.

---

But it has already been tried!

I can see that. Try it after changing the open mode to +<.

According to perldoc perlfaq5:

How come when I open a file read-write it wipes it out?

Because you’re using something like this, which truncates the file
then gives you read-write access:

  open my $fh, '+>', '/path/name'; # WRONG (almost always)

Whoops. You should instead use this, which will fail if the file
doesn’t exist:

  open my $fh, '+<', '/path/name'; # open for update

Using ">" always clobbers or creates. Using "<" never does either. The
"+" doesn’t change this.

It goes without saying that the or die $! after the open is highly recommended.

---

But take a step back.

There is a more Perlish way to back up the original file and subsequently manipulate it. In fact, it is doable via the command line itself (!) using the -i flag:

$ perl -p -i._extjs4 -e 's/foo/bar/g' *.js

See perldoc perlrun for more details.

---

I can’t fit my needs into the command-line.

If the manipulation is too much for the command-line to handle, the Tie::File module is worth a try.