Question

I’m in the process of creating a Java analyzer for an ANTLR grammar that someone else is writing.

Is it possible to combine ANTLR files so that I can add my bracketed Java code to the ANTLR-generated Java files through a file separate from the original grammar (.g) file? I’ve investigated composite grammars, but it doesn’t seem as though I can import the existing grammar as a combined lexer/parser.

For instance, can I do something like this:

Grammar.g

grammar Grammar;

statement   : first=WORD ';' ;
WORD        : ('A'..'z')* ;

JavaGrammar.g

grammar JavaGrammar;
imports Grammar;

@header {
    package pkg;
    import Container;
}

@lexer::header {
    package pkg;
}

@members{
    Container c = null;
    public void setContainer(Container c) { this.c = c; }

    @Override
    protected Object recoverFromMismatchedToken(IntStream input, int ttype, BitSet follow) throws RecognitionException {
      throw new MismatchedTokenException(ttype, input);
    }

    @Override
    public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow) throws RecognitionException {
      throw e;
    }
}

@rulecatch {
    catch (RecognitionException e) {
        throw e;
    }
}

jStatement: statement { if(c!=null) c.add($first.text); } ;

Answer 1

You can’t import (it’s import, btw, not imports) a combined grammar. See the ANTLR Wiki:

Please note that a combined grammar may not import a combined grammar. This may seem to limit the depth of imports but it’s not the case. Parser grammars don’t need to explicitly import the lexer grammar they rely on, this is done only once in the root composite grammar which “glues” its dependent grammars.

— http://www.antlr.org/wiki/display/ANTLR3/Composite+Grammars

And you can’t use a label (the first in your statement rule) outside of the rule it exists in.

What you can do is this:

file: L.g

lexer grammar L;

WORD : ('A'..'z')* ;
SCOL : ';';

file: P.g

parser grammar P;

statement returns[String first, String last]
 : WORD SCOL
   {
     $first = $WORD.text;
     $last = $SCOL.text;
   }
 ;

file: JavaGrammar.g

grammar JavaGrammar;

import P, L;

@parser::members {
  public static void main(String[] args) throws Exception {
    L lexer = new L(new ANTLRStringStream("SO;"));
    JavaGrammarParser parser = new JavaGrammarParser(new CommonTokenStream(lexer));
    parser.jStatement(); 
  }
}

jStatement
 : statement 
   {
     System.out.println("statement       = '" + $statement.text + "'\n" + 
                        "statement.first = '" + $statement.first + "'\n" + 
                        "statement.last  = '" + $statement.last + "'");
   } 
 ;

Run the class with the main method:

java -cp antlr-3.3-complete.jar org.antlr.Tool *.g
javac -cp antlr-3.3-complete.jar *.java
java -cp .:antlr-3.3-complete.jar JavaGrammarParser

and you’ll see the following being printed to the console:

statement       = 'SO;'
statement.first = 'SO'
statement.last  = ';'