Question

I’m learning f# from msdn and looking and trying out the reduce and reduce back, I can’t find any difference, the signature is the same

('T -> 'T -> 'T) -> 'T list -> 'T

and they both throw same error on empty list, so why is there 2 of them, there should be some difference

Answer 1

Others already explained the difference – they reduce elements in a different order.

For most of the operations that you can use with reduce or reduceBack, the difference does not actually matter. In more mathematical terms, if your operation is associative (such as numeric operations, max, min or sum functions, list concatenation, etc.) then the two behave the same.

An example where you can nicely see the difference is building a tree, because that exactly shows how the evaluation works:

type Tree = 
  | Leaf of int
  | Node of Tree * Tree

[ for n in 0 .. 3 -> Leaf n]
|> List.reduce (fun a b -> Node(a, b))

[ for n in 0 .. 3 -> Leaf n]
|> List.reduceBack (fun a b -> Node(a, b))

Here are the two trees that you get as the result (but note that if you flatten them, then you get the same list!)

          reduce        reduceBack
-------------------------------------
tree:       /\              /\
           /\ 3            0 /\
          /\ 2              1 /\
         0  1                2  3
-------------------------------------
flat:    0 1 2 3          0 1 2 3