Question

I’m looking at some older Perl code on Perl Monks to figure out programming with Win32::OLE and MS Word. Scattered throughout the code are variables with names like $MS::Word and the like, without a ‘my‘ included in their declaration. After reading a bit on Google, I understand that these are called ‘package variables’ versus ‘lexical variables’ declared using my.

My first question is ‘What are package variables good for?‘. I (think) I understand what lexical variables are, but I don’t understand the purpose of package variables or how their use differs from lexicals, so my second question would be, ‘What is the difference between lexical and package variables?‘

Answer 1

A package variable lives in a symbol table, so given its name, it’s possible to read or modify it from any other package or scope. A lexical variable’s scope is determined by the program text. The section “Private Variables via my()” in the perlsub manpage gives more detail about defining lexicals.

Say we have the following MyModule.pm:

package MyModule;

# these are package variables
our $Name;
$MyModule::calls = "I do not think it means what you think it means.";

# this is a lexical variable
my $calls = 0;

sub say_hello {
  ++$calls;

  print "Hello, $Name!\n";
}

sub num_greetings {
  $calls;
}

1;

Notice that it contains a package $calls and a lexical $calls. Anyone can get to the former, but the module controls access to the latter:

#! /usr/bin/perl

use warnings;
use strict;

use MyModule;

foreach my $name (qw/ Larry Curly Moe Shemp /) {
  $MyModule::Name = $name;
  MyModule::say_hello;
}

print MyModule::num_greetings, "\n";

print "calls = $MyModule::calls\n";

The program’s output is

Hello, Larry!
Hello, Curly!
Hello, Moe!
Hello, Shemp!
4
calls = I do not think it means what you think it means.

As you can see, package variables are globals, so all the usual gotchas and advice against apply. Unless explicitly provided access, it’s impossible for code outside the MyModule package to access its lexical $calls.

The rule of thumb is you very nearly always want to use lexicals. Perl Best Practices by Damian Conway is direct: “Never make variables part of a module’s interface” (emphasis in original).