Question

I’m looking at the Adobe documentation here and it’s not clear.

Since I’m having an issue with my app I’m wondering if it could be because I’m evaluating two sprites, one that is on the stage and the other that is created but no addChild’ed

Answer 1

Actually, the answer depends on which platform you are targeting. In FlashPlayer, hitTestObject just checks if the bounding boxes of the objects overlap, so as long as you have the correct x and y positions and the correct width and height for your objects you don’t need them to actually be on the stage.

However, in AIR, probably some kind of code optimization is taking place, and if one of the objects is not actually on the stage it will return false

Let’s just tinker a little with the example from the docs, removing just one addChild:

import flash.display.Shape;

var circle1:Shape = new Shape();
circle1.graphics.beginFill(0x0000FF);
circle1.graphics.drawCircle(40, 40, 40);
//addChild(circle1);

var circle2:Shape = new Shape();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(40, 40, 40);
circle2.x = 50;
addChild(circle2);

var circle3:Shape = new Shape();
circle3.graphics.beginFill(0xFF0000);
circle3.graphics.drawCircle(40, 40, 40);
circle3.x = 100;
circle3.y = 67;
addChild(circle3);

trace(circle1.hitTestObject(circle2)); 
trace(circle1.hitTestObject(circle3));
trace(circle2.hitTestObject(circle3));

In FP10 we get the following output:

true
false
true

However, in AIR we get:

false
false
true

The key difference is that hitTestObject between the circle1 and circle2 is false in AIR because circle1 has not been added to the stage, but in FlashPlayer is true anyways. Thanks to @user1113426 for pointing there was something amiss here!