Question

I’m looking for a simple/elegant way to grep a file such that every returned line must match every line of a pattern file.

With input file

acb
bc
ca
bac

And pattern file

a
b
c

The command should return

acb
bac

I tried to do this with grep -f but that returns if it matches a single pattern in the file (and not all). I also tried something with a recursive call to perl -ne (foreach line of the pattern file, call perl -ne on the search file and try to grep in place) but I couldn’t get the syntax parser to accept a call to perl from perl, so not sure if that’s possible.

I thought there’s probably a more elegant way to do this, so I thought I’d check. Thanks!

===UPDATE===

Thanks for your answers so far, sorry if I wasn’t clear but I was hoping for just a one-line result (creating a script for this seems too heavy, just wanted something quick). I’ve been thinking about it some more and I came up with this so far:

perl -n -e 'chomp($_); print " | grep $_  "' pattern | xargs echo "cat input"

which prints

cat input | grep a | grep b | grep c

This string is what I want to execute, I just need to somehow execute it now. I tried an additional pipe to eval

perl -n -e 'chomp($_); print " | grep $_  "' pattern | xargs echo "cat input" | eval

Though that gives the message:

xargs: echo: terminated by signal 13

I’m not sure what that means?

Answer 1

One way using perl:

Content of input:

acb
bc
ca
bac

Content of pattern:

a
b
c

Content of script.pl:

use warnings;
use strict;

## Check arguments.
die qq[Usage: perl $0 <input-file> <pattern-file>\n] unless @ARGV == 2;

## Open files.
open my $pattern_fh, qq[<], pop @ARGV or die qq[ERROR: Cannot open pattern file: $!\n];
open my $input_fh, qq[<], pop @ARGV or die qq[ERROR: Cannot open input file: $!\n];

## Variable to save the regular expression.
my $str;

## Read patterns to match, and create a regex, with each string in a positive
## look-ahead.
while ( <$pattern_fh> ) { 
    chomp;
    $str .= qq[(?=.*$_)];
}

my $regex = qr/$str/;

## Read each line of data and test if the regex matches.
while ( <$input_fh> ) { 
    chomp;
    printf qq[%s\n], $_ if m/$regex/o;
}

Run it like:

perl script.pl input pattern

With following output:

acb
bac