Question

Im looking for a XSLT (1.0) stylesheet.
I have input similar to this:

<?xml version="1.0" encoding="ISO-8859-1"?>

<city country="USA">
Washington
</city> 

<city country="USA">
New York
</city> 

<city country="Germany">
Berlin
</city> 

<country size="big">
USA
</country>


<country size="small">
Germany
</country>

I want output like this:

Country USA 
Size: big
Cities: 
Washington
New York

Country Germany
Size: small
Cities:
Berlin

I am trying something like a nested for-each loop. But I dont know how to access the node when im inside the other node.

If this is a duplicate question I am sorry: the problem might be that I dont really know how to express my problem to find similar questions.

Answer 1

Nested loops are not necessary. The following stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <xsl:apply-templates select="/*/country"/>
    </xsl:template>
    <xsl:template match="country">
        <xsl:text>Country </xsl:text> 
        <xsl:value-of select="."/>
        <xsl:text>&#xa;Size: </xsl:text>
        <xsl:value-of select="@size"/>
        <xsl:text>&#xa;Cities:&#xa;</xsl:text>
        <xsl:apply-templates select="../city[@country=current()/text()]"/>
        <xsl:text>&#xa;</xsl:text>
    </xsl:template>
    <xsl:template match="city">
        <xsl:apply-templates/>
        <xsl:text>&#xa;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

Applied to this input:

<root>
    <city country="USA">Washington</city>
    <city country="USA">New York</city>
    <city country="Germany">Berlin</city>
    <country size="big">USA</country>
    <country size="small">Germany</country>
</root>

Produces:

Country USA
Size: big
Cities:
Washington
New York

Country Germany
Size: small
Cities:
Berlin

Note: The input you provided includes a lot of significant whitespace, which I removed in my example.