Question

I’m new to emacs lisp programming. I’m a developer and programming in c on daily basis. I would like to use tags for code browsing with emacs. However, size of my project very big and cant afford to run etags every now and then. I would like add lisp function or code in emacs in such a way, every file i open emacs has to written to one file (name it as ~/project_files_opened.txt) and i will cron job which will etags only the opened files.. Can someone please help me with some references or existing code to do this ?. Even some examples would help me to pick up… Thanks..

Answer 1

How about a slightly different tact? When you open a file (that you care about), at that point, add it to the TAGS file. You can do that pretty easily with the following code:

(setq tags-file-name "/scratch2/TAGS")
(setq tags-revert-without-query t)
(add-hook 'find-file-hooks 'add-opened-file-to-tags)
(defun add-opened-file-to-tags ()
  "every time a file is opened, add it to the TAGS file (if not already present)
Note: only add it to the TAGS file when the major mode is one we care about"
  (when (memq major-mode '(c-mode c++-mode))
(let ((opened-file (buffer-file-name)))
  (save-excursion
    (visit-tags-table-buffer)
    (unless (member opened-file (tags-table-files))
      (shell-command 
            (format "etags -a --output %s %s" tags-file-name opened-file)))))))
;; create an empty TAGS file if necessary
(unless (file-exists-p tags-file-name)
  (shell-command (format "touch %s" tags-file-name)))

Every once in a while you’ll want to delete the TAGS file to refresh the contents. Or you can use something like the following M-x refresh-tags-table:

(defun refresh-tags-file ()
  "rebuild the tags file"
  (interactive)
  (let ((tags-files 
     (save-excursion
       (visit-tags-table-buffer)
       (tags-table-files))))
(delete-file tags-file-name)
(dolist (file tags-files)
  (shell-command (format "etags -a --output %s %s" tags-file-name file)))))