Question

I’m new to haskell and I’m attempting to write my first haskell C library. This is my first time using the Foreign.C module. I’m getting lost in examples and have become stuck. This is what I have come up with so far:

{-# LANGUAGE ForeignFunctionInterface #-}

module Grep where

import GHC.Ptr
import Foreign.C.String
import Data.List (isInfixOf)

grep :: CString -> CString -> CString
grep i s = do
    ii <- peekCString i
    ss <- peekCString s
    g <- newCString (isInfixOf ii ss)
    g 

foreign export ccall grep :: CString -> CString -> CString

I get the following error:

PS C:\Users\GGuy\Source\haskell> ghc -c -O grep.hs

grep.hs:11:9:
  No instance for (Monad Ptr)
    arising from a do statement
  Possible fix: add an instance declaration for (Monad Ptr)
  In a stmt of a 'do' block: ii <- (peekCString i)
  In the expression:
    do { ii <- (peekCString i);
      ss <- peekCString s;
      g <- newCString (isInfixOf ii ss);
      g }
  In an equation for `grep':
    grep i s
      = do { ii <- (peekCString i);
             ss <- peekCString s;
             g <- newCString (isInfixOf ii ss);
             .... }

grep.hs:11:16:
  Couldn't match expected type `Ptr t0' with actual type `IO String'
  In the return type of a call of `peekCString'
  In a stmt of a 'do' block: ii <- (peekCString i)
  In the expression:
    do { ii <- (peekCString i);
       ss <- peekCString s;
       g <- newCString (isInfixOf ii ss);
       g }

Answer 1

Now that the fix

grep :: CString -> CString -> IO Bool
grep i s = do
    ii <- peekCString i
    ss <- peekCString s
    return (isInfixOf ii ss)

foreign export ccall grep :: CString -> CString -> IO Bool

is clarified, let us find out how the error messages come to be:

grep :: CString -> CString -> CString
grep i s = do
    ii <- peekCString i
    ss <- peekCString s
    g <- newCString (isInfixOf ii ss)
    g

The declared result type of grep is CString, which is a type synonym for Ptr CChar. The right hand side of the definition is a do-block (with more than one statement), so the result type must have the form m a for some Monad m and some type a.

The declared result type Ptr CChar matches the form m a – with m = Ptr, a = CChar – and so what remains is to find/verify the Monad instance of the type constructor Ptr. There is none in scope, hence

grep.hs:11:9:
  No instance for (Monad Ptr)              -- quite
    arising from a do statement            -- right
  Possible fix: add an instance declaration for (Monad Ptr)    -- Umm, no, not really

the first reported error.

The second error comes from analysing the contents of the do-block. The compiler could have stopped type-checking upon encountering the first error, but didn’t. Now the further type checking continues under the assumption that Ptr were a Monad. So in that do-block, every expression on the right of a <- (which, after desugaring becomes the first argument of a (>>=) :: Monad m => m a -> (a -> mb) -> m b), must have type Ptr sometype. But peekCString :: CString -> IO String, thus

grep.hs:11:16:
  Couldn't match expected type `Ptr t0' with actual type `IO String'
  In the return type of a call of `peekCString'
  In a stmt of a 'do' block: ii <- (peekCString i)
  In the expression:
    do { ii <- (peekCString i);
       ss <- peekCString s;
       g <- newCString (isInfixOf ii ss);
       g }

If the compiler continued, it would give the same type error for the second peekCString line, and finally a

Couldn't match type `Bool' with `[Char]'
Expected type: String
  Actual type: Bool
In the first argument of `newCString', namely ...

for the wrongly typed argument of newCString (plus another IO – Ptr mismatch).