Question

I’m new to SQLServer scripting (normally being a C++ developer), and would really appreciate a bit of assistance.

I am attempting to perform a “find and replace” update on all tables in a SQLServer database that contain a ‘PROJID’ column. I am really struggling to find a way to do this that doesn’t report to me:

Msg 207, Level 16, State 1, Line 1 Invalid column name ‘PROJID’.

The statement I am executing is:

EXEC
(
  'IF EXISTS(SELECT * FROM sys.columns WHERE name = N''PROJID'' AND Object_ID = Object_ID(N''' + @TableName + '''))' +
  ' BEGIN' +
  ' UPDATE ' + @TableName + 
  ' SET ' + @ColumnName + ' = REPLACE(' + @ColumnName + ',''' + @ReplaceIDStr + ''',''' + @FindIDStr + ''')' +
  ' WHERE ' + @ColumnName + ' LIKE ''' + @ReplaceIDStr + '''' + ' AND PROJID = ''1000''' +
  ' END'
)

I have also tried using:

'IF COL_LENGTH(''' + @TableName + ''',''PROJID'') IS NOT NULL' +

instead of the column-exist check above. This also still gives me the “Invalid Column Name” messages.

I would be happy to take the column-exist check outside of the ‘Exec’ statement, but I’m not sure how to go about doing this either.

Answer 1

Output the results of this query to text. Don’t forget to change the values of the variables! Take the result of this and run it.

SET NOCOUNT ON

DECLARE @ColumnName VARCHAR(200) = 'ReplaceColumn'
    , @ReplaceIdStr VARCHAR(200) = 'ExampleReplaceIdStr'
    , @FindIdStr VARCHAR(200) = 'ExampleFindIdStr'

PRINT 'BEGIN TRAN'
PRINT 'SET XACT_ABORT ON'

SELECT
    'UPDATE ' + C.TABLE_NAME + CHAR(13)
    + 'SET ' + @ColumnName + ' = REPLACE(' + @ColumnName + ', ''' + @ReplaceIdStr + ''', ''' + @FindIdStr + ''')' + CHAR(13)
    + 'WHERE ' + @ColumnName + ' LIKE ''%' + @ReplaceIdStr + '%'' AND PROJID = ''1000''' + CHAR(13)
FROM INFORMATION_SCHEMA.COLUMNS C
WHERE C.COLUMN_NAME = 'PROJID'

PRINT 'COMMIT TRAN'

SET NOCOUNT OFF

EDIT: Also, some reasoning: You said you want update all tables where they contain a column called PROJID. Your first query just says that if the table @TableName has a PROJID column, then update @ColumnName on it. But it doesn’t guarantee that it has @ColumnName on it. The query I gave doesn’t check that either, because I’m assuming that all tables that have PROJID also have @ColumnName. If that isn’t the case, let me know and I can update the answer to check that. That you’re getting an Invalid Column Name error points to @ColumnName not existing.

Your query would have updated one table (@TableName) at most, whereas the one I gave you will update every table that has PROJID. I hope that’s what your going for.

EDIT 2: Here is a version that would run it all at once:

DECLARE @ColumnName VARCHAR(200) = 'Value'
    , @ReplaceIdStr VARCHAR(200) = 'ExampleReplaceIdStr'
    , @FindIdStr VARCHAR(200) = 'ExampleFindIdStr'


DECLARE @Sql NVARCHAR(MAX)
DECLARE UpdateCursor CURSOR FOR
SELECT
    'UPDATE ' + C.TABLE_NAME
    + ' SET ' + @ColumnName + ' = REPLACE(' + @ColumnName + ', ''' + @ReplaceIdStr + ''', ''' + @FindIdStr + ''')'
    + ' WHERE ' + @ColumnName + ' LIKE ''%' + @ReplaceIdStr + '%'' AND PROJID = ''1000'''
FROM INFORMATION_SCHEMA.COLUMNS C
WHERE C.COLUMN_NAME = 'PROJID'

OPEN UpdateCursor

FETCH NEXT FROM UpdateCursor
INTO @Sql

WHILE @@FETCH_STATUS = 0
BEGIN
    EXEC sp_executesql @Sql

    FETCH NEXT FROM UpdateCursor
    INTO @Sql
END


CLOSE UpdateCursor
DEALLOCATE UpdateCursor