Question

I’m new to XSL and I’m looking for a way to replace text in XML.
My source XML is:

<A>
 <key>One</key>
 <string>value1</string>
 <key>Two</key>
 <string>value2</string>
 <key>Three</key>
 <string>value3</string>
</A>

What I want is to replace only one of the element.
The result should be:

<A>
 <key>One</key>
 <string>value1</string>  
 <key>Two</key>
 <string>xxx</string>  <---- change this (for key Two)
 <key>Three</key>
 <string>value3</string>
</A>

How to create an xsl stylesheet to manage this?

Thanks in advance!

Answer 1

This seems to do the trick:

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="string">
    <xsl:choose>
      <xsl:when test="preceding-sibling::key[position() = 1 and text() = 'Two']">
        <string>replacement</string>
      </xsl:when>
      <xsl:otherwise>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>  
      </xsl:otherwise>
    </xsl:choose>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>  
    </xsl:template>
</xsl:stylesheet>

The key fragment is the use of the preceding-sibling axis. All available axes are documented here in the xpath specification.