Question

I’m new user and i need you help with a prolog program.

The sailing club “Thalassa” recently held a contest for young sailors, with boats of two people. The crew of each vessel was a boy and a girl.

1. One member of the crew of the vessel “Ostria” was “Argiris”.
2. Magda was neither with “Miltos” nor with “Taki”. “Xronis” and “Maro” was not in the “Albatross” and not finished in 24 minutes.
3. “Olga” aboard the “Batis”, while the “Aetos” did not finish in 27 minutes.
4. In “Thiella” was or “Miltos” or “Takis” and not aboard the “Basia”.
5. “Xara” finished in 16 minutes. “Olga” took more time than “Magda” to finish.
6. “Takis” with her ​​partner finished the race in 21 minutes.

Vessel: “Aetos, “Ostria”, “Batis”, “Albantros”, “Thiella”
Men: “Miltos”, “Takis”, “Argiris”, “Xronis”, “Foibos”
wemen: “Maro”, “Olga”, “Basia”, “Magda”, “Xara”
times: “16”, “19”, “21”, “24”, “27”

i need a program to ask ? solve(X) and gives me a list with the right combination
e.g. X=Aetos, Takis, Maro, 16

Answer 1

edit: I missed the “eclipse” tag, so perhaps this isn’t the answer you’re looking for. It works in plain Prolog though, i.e. SWI.

---

So you do have the enumeration of participants, at least we don’t need to deduce that. Start with it:

• Vessel: “Aetos, “Ostria”, “Batis”, “Albatross”, “Thiella”
• Men: “Miltos”, “Takis”, “Argiris”, “Xronis”, “Foibos”
• women: “Maro”, “Olga”, “Basia”, “Magda”, “Xara”
• times: “16”, “19”, “21”, “24”, “27”

Rules: Use the times as values!:

1  Argiris = Ostria,
2  Magda \= Miltos, Magda \= Takis,     
   Xronis \= Albatross, Maro \= Albatross, Xronis \= 24, Maro \= 24, 
     %% does that mean they were together in one boat??
3  Olga = Batis, Aetos \= 27,  
4  ( Thiella = Miltos  ;  Thiella = Takis) ,  Thiella \= Basia,
5  Xara = 16, Olga > Magda,
6  Takis = 21

Use select/2 for domain selection:

select([A|B], C):- select(A,C,C2), select(B,C2).
select([],_).

We’re ready to start coding. The most definite statements go first. It is important to not test any variable until it is defined:

sailing(_Vars):-
  Dom = [16,19,21,24,27],     %% the domain
  Takis = 21, 
  select( [Takis, Miltos, Argiris, Xronis, Foibos], Dom), Xronis \= 24, 
  Xara = 16,  
  select( [Xara,  Maro,   Magda,   Olga,   Basia],  Dom), Maro \= 24,
  Magda \= Takis, Magda \= Miltos, Olga > Magda, 
  Olga = Batis, Argiris = Ostria, 
  select( [Batis, Ostria, Aetos, Albatross, Thiella], Dom), Aetos \= 27,
  Thiella \= Basia, 
  (Thiella = Miltos  ;  Thiella = Takis),
  Xronis \= Albatross, Maro \= Albatross.

This gives me 57 solutions. So perhaps Xronis and Maro do need to be put into same boat. Try it.

---

How to report your answer is an additional concern. The above shows the solver.

One way is to tweak the above code as e.g.

solve([Takis, Miltos, Argiris, Xronis, Foibos]) :- ... .

and call it as ?- solve(Men), to see the time assignments for each of Men. Another is to alter the code as e.g.

pair( A-B, A, B).

solve(Result) :-
  ... ,
  keysort( [Takis-'Takis', Miltos-'Miltos', Argiris-'Argiris',
                          Xronis-'Xronis', Foibos-'Foibos'], TM),
  maplist( pair,TM,Times,Men),
  keysort( [Xara-'Xara',  Maro-'Maro',   Magda-'Magda',   
                         Olga-'Olga',   Basia-'Basia'], TW),
  maplist( pair,TW,Times,Women),
  ... ,
  maplist( pair,TV,Times,Vessels),
  Result = [Vessels,Men,Women,Times],
  maplist( writeln, Result).

If you further want to convert the four lists in Result into one transposed list of combined data, you can do that too with few more maplist/4 calls, e.g.

maplist( pair,VM,Vessels,Men), maplist( pair,WT,Women,Times),
maplist( quad,Result,VM,WT).

quad( (A,B,C,D), A-B, ... ).