Question

I’m really new to flash and as3…
I’m trying to create 2 scenes in flash – one where my movieclip moves away from the mouse whenever it goes near it, and the other where the movie clip is attracted to the mouse. I have found an answer on actionscript 2 but i cannot use this in my as3 file…
Any help or ideas?
Cheers!

Answer 1

Here is an example I made of a display object being “pushed” and “pulled” in relation to the mouse’s position.

Main.as(Document class):

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.geom.Point;

    public class Main extends Sprite  
    {

        public static var PULL:String = "pull";
        public static var PUSH:String = "push";

        private var _circle:Circle;
        private var _force:String;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            _circle = new Circle();
            addChild(_circle);

            _force = PULL;

            stage.addEventListener(MouseEvent.MOUSE_DOWN, onStageMouseDown);

        }// end function

        private function onStageMouseDown(e:MouseEvent):void 
        {
            stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
            stage.addEventListener(Event.ENTER_FRAME, onStageEnterFrame);

        }// end function

        private function onStageMouseUp(e:MouseEvent):void 
        {
            stage.removeEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
            stage.removeEventListener(Event.ENTER_FRAME, onStageEnterFrame);

            _force = (_force == PULL) ? PUSH : PULL;

        }// end function

        private function onStageEnterFrame(e:Event):void 
        {
            var point1:Point = new Point(_circle.x, _circle.y);
            var point2:Point = new Point(stage.mouseX, stage.mouseY);
            var point3:Point = point2.subtract(point1);
            point3.normalize(10);

            if (_force == PULL) {

                _circle.x += point3.x;
                _circle.y += point3.y;

            } else if (_force == PUSH) {

                _circle.x -= point3.x;
                _circle.y -= point3.y;

            }// end else if

        }// end function

    }// end class

}// end package

import flash.display.Sprite;
import flash.events.Event;

class Circle extends Sprite {

    public function Circle() {

        draw();

    }// end function

    private function draw():void {

        this.graphics.lineStyle(1);
        this.graphics.beginFill(0xFFFFFF);
        this.graphics.drawCircle( 0, 0, 20);
        this.graphics.endFill();

    }// end function

}// end class

In the init() method we add a new display object to the stage, this is the display object we will be “pulling” and “pushing” in relation to the mouse’s position.

_circle = new Circle();
addChild(_circle);

Then we set the _force property to our PULL constant. The _force property will determine whether the display object is “pulled” or “pushed”.

_force = PULL;

Next we add our mouse event listeners to the stage. On MouseEvent.MOUSE_DOWN we call the onStageMouseDown() event handler. When the handler is called, we add an Event.ENTER_FRAME and MouseEvent.MOUSE_UP event listeners to the stage.

private function onStageMouseDown(e:MouseEvent):void 
{
    stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
    stage.addEventListener(Event.ENTER_FRAME, onStageEnterFrame);

}// end function

When the MouseEvent.MOUSE_UP event handler is called, the previous Event.ENTER_FRAME and MouseEvent.MOUSE_UP event listeners are removed from the stage. Then depending on the _force property’s value, its value is alternated between PUSH and PULL.

private function onStageMouseUp(e:MouseEvent):void 
{
    stage.removeEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
    stage.removeEventListener(Event.ENTER_FRAME, onStageEnterFrame);

    _force = (_force == PULL) ? PUSH : PULL;

}// end function

Lastly, the onStageEnterFrame event handler. This is where we calculate the new position of the display object in relation to the mouse.

There are different ways to go about this, but I decided to use the Point class to simplify things. First we have to get a Point object for the display object’s position and another Point object for mouse’s position.

var point1:Point = new Point(_circle.x, _circle.y);
var point2:Point = new Point(stage.mouseX, stage.mouseY);

Next we have to get the difference between the points using the Point object’s subtract() method.

var point3:Point = point2.subtract(point1);

With this new point, we can use the Point object’s normalize() method to scale the line segment between the display object’s position and the mouse’s position to a set length.

point3.normalize(10);

Finally depending on the _force property’s value we either subtract or add the point’s x and y properties from the display object’s x and y properties.