Question

I’m running a vbs file using a keyboard shortcut. Although the code runs fine, the problem with vbs shortcuts is that the window in the foreground loses its focus as soon as you press the keyboard shortcut. (You can try it for yourself by placing an empty vbs file somewhere, a shortcut to the file in e.g. the start menu folder, a keyboard shortcut assigned to the shortcut and pressing the keyboard shortcut.)

I found that by using ALT+TAB, I could get the foreground window to regain focus. However, I’m unable to repeat this functionality in VBA. Apparently, ShellObject.SendKeys("%{TAB}") doesn’t work…

Is there any way to achieve the functionality of ALT+TAB in VBA? Thanks in advance.

EDIT

In the meanwhile, I made a switch to AutoIt to see if it could get me further. This is what I got:

ControlFocus("[CLASS:CabinetWClass]", "", "[CLASS:DirectUIHWND]")

I noticed that selecting the explorer window (i.e. CabinetWClass), is in some cases not enough. That’s why I’m setting focus on the control that actually contains the files/folders.

It’s working very well, but I’m still hoping for a VBA solution 🙂

Answer 1

Can you use the Windows APIs to bring it back to the top? This works for me when run in Excel to bring the notepad to the top, so it should work. You would have to substitute the name of your window in the FindWindow call.

Note: You should be really carefull with some of the flags because you’ll get some weird behaviour if you do some wrong combinations of them.

Public Declare Function FindWindow Lib "user32" _
    Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long


Declare Function SetWindowPos Lib "user32.dll" (ByVal hwnd As _
        Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As _
        Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

'Either the handle of the window to position this window behind, or exactly one of the following flags stating where in the
'Z-order to put the window:
Private Const HWND_BOTTOM = 1             'Put the window at the bottom of the Z-order.
Private Const HWND_NOTOPMOST = -2         'Put the window below all topmost windows and above all non-topmost windows.
Private Const HWND_TOP = 0                'Put the window at the top of the Z-order.
Private Const HWND_TOPMOST = -1           'Make the window topmost (above all other windows) permanently.

'x: The x coordinate of where to put the upper-left corner of the window.
'y: The y coordinate of where to put the upper-left corner of the window.
'cx: The x coordinate of where to put the lower-right corner of the window.
'cy: The y coordinate of where to put the lower-right corner of the window.

'Flags: Zero or more of the following flags stating how to move the window:
Private Const SWP_DRAWFRAME = &H20            'Same as SWP_FRAMECHANGED.
Private Const SWP_FRAMECHANGED = &H20         'Fully redraw the window in its new position.
Private Const SWP_HIDEWINDOW = &H80           'Hide the window from the screen.
Private Const SWP_NOACTIVATE = &H10           'Do not make the window active after moving it unless it was already the active window.
Private Const SWP_NOCOPYBITS = &H100          'Do not redraw anything drawn on the window after it is moved.
Private Const SWP_NOMOVE = &H2                'Do not move the window.
Private Const SWP_NOSIZE = &H1                'Do not resize the window.
Private Const SWP_NOREDRAW = &H8              'Do not remove the image of the window in its former position, effectively leaving a ghost image on the screen.
Private Const SWP_NOZORDER = &H4              'Do not change the window's position in the Z-order.
Private Const SWP_SHOWWINDOW = &H40           'Show the window if it is hidden.


Sub ShowWindow()
    Dim hwnd As Long 'handle to get the window
    Dim flags As Long ' the flags specifying how to move the window
    Dim retval As Long ' return value

    hwnd = FindWindow(vbNullString, "Untitled - Notepad")
    flags = SWP_NOSIZE Or SWP_DRAWFRAME
    retval = SetWindowPos(hwnd, HWND_TOP, 0, 0, 1, 1, flags) ' move the window
End Sub