Question

I’m stumped. I’m currently trying to create a time off tracker for time off.

I have two tabs.

First tab: “Overview” – This tab has three columns.

• Month

• Amt Used

  =SUMIFS(Data!$C:$C,Data!$A:$A,"January")
  

  This formula access the data tab, and uses the first column information and sums the amount for that month.

• Amt Left
  Jan

  =B5+$G$4
  

  Feb

  =C5+B6+$G$4
  

  This adds the amount left, with amount used and adds the accrual rate with it each month.

Then to the right, I have “Accrual Rate” and the cell next to it is variable. It is the place to put the amount of hours accrued in a month. (The forumla will multiple it by 12 months to simplify for the user)

Done with first tab.

Second tab: Called “Data”

This is where one can put their days off.

This is nothing fancy. Three untitled columns.

• a cell with a formula:

  =IF(B1="","",TEXT(B1,"mmmmmmmm"))
  

• Next column is the date in mm/dd/yyyy format.
• Next column is the amount of hours used. Negative for “using hours” and positive number for “gaining hours”.

Now, maybe I did not need a long explantion to ask this question. I’m trying to remove the column that figures out the month. Is there a way to use the Sumif command to find by date within the formula?

If the dates are:

1/1/2013 | -8 |

1/2/2013 | -8 |

1/3/2013 | -8 |

1/4/2013 | -8 |

2/2/2013 | -8 |

2/3/2013 | -8 |

2/4/2013 | -8 |

Is there a way to say, if the month is “1” or Jan, sum the total of the cell next to it? In this case, the answer should be 32.

Answer 1

With SUMIFS you could sum between 1st and 31st Jan, e.g.

=SUMIFS(Data!$C:$C,Data!$B:$B,">="&DATE(2013,1,1),Data!$B:$B,"<="&DATE(2013,1,31))

or probably better to reference a cell with the date, so say you have 1st Jan 2013 in B3 in Overview tab that would be:

=SUMIFS(Data!$C:$C,Data!$B:$B,">="&B3,Data!$B:$B,"<="&EOMONTH(B3,0))

The latter formula can be copied down for multiple months