Question

I’m trying to change an xml by using regular expressions in java, but I can’t find the right way. I have an xml like this (simplified):

<ROOT>
   <NODE ord="1" />
   <NODE ord="3,2" />
</ROOT>

The xml actually shows a sentence with its nodes, chunks … in two languages and has more attributes. Each sentence it’s loaded in two RichTextAreas (one for the source sentence, and the other for the translated one).

What I need to do is add a style attribute to every node that has an specific value in its ord attribute (this style attribute will show correspondences between two languages, like Google Translate does when you mouse over a word). I know this could be done using DOM (getting all the NODE nodes and then seeing the ord attribute one by one), but I am looking for the fastest way to do the change as it is going to execute in the client side of my GWT app.

When that ord attribute has a single value (like in the first node) it is easy to do just taking the xml as a string and using the replaceAll() function . The problem is when the attribute has composed values (like in the second node).

For example, how could I do to add that attribute if the value I’m looking for is 2? I believe this could be done using regular expressions, but I can’t find out how. Any hint or help would be appreciated (even if it doesn’t use regexp and replaceAll function).

Thanks in advance.

Answer 1

XPath can do this for you. You could select:

/ROOT/NODE[contains(concat(',', @ord, ','), ',2,')]

Since you intend to use GWT on the client, you could give gwtxslt a try. With it you could specify an XSLT stylesheet to do the transformation (i.e. adding the attribute) for you:

XsltProcessor processor = new XsltProcessor();
processor.importStyleSheet(styleSheetText);
processor.importSource(sourceText);
processor.setParameter("ord", "2");
processor.setParameter("style", "whatever");
String resultString = processor.transform();
// do something with resultString

where styleSheetText could be an XSLT document along the lines of

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:param name="ord"   select="''" />
  <xsl:param name="style" select="''" />

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="NODE">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
      <xsl:if test="contains(concat(',', @ord, ','), concat(',', $ord, ','))">
        <xsl:attribute name="style">
          <xsl:value-of select="$style" />
        </xsl:attribute>
      </xsl:if>
      <xsl:apply-templates select="node()" />
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Note that I use concat() to prevent partial matches in the comma-separated list that the attribute value of @ord actually is.