Question

I’m trying to convert a Maybe value to a Char. I get the following error and despite my best efforts I can’t figure out how to correct this.

convertmaybe.hs:18:22:
    No instance for (ToChar a)
      arising from a use of `toChar'
    In the expression: toChar a
    In an equation for `showMaybe': showMaybe (Just a) = toChar a
Failed, modules loaded: none.

This is the code:

class ToChar a where
    toChar :: a -> Char
instance ToChar Char where
    toChar = id
instance ToChar Int where
    toChar = head . show

showMaybe :: Maybe a -> Char
showMaybe Nothing = ' '
showMaybe (Just a) = toChar a

What am I doing wrong here?

Answer 1

What you are missing is the constraint in your showMaybe type signature. Your current signature

showMaybe :: Maybe a -> Char

says that this function should work for all types a, but it really only
works for types that are instances of the ToChar type class. You can fix
this by adding the constraint to your type signature as such

showMaybe :: (ToChar a) => Maybe a -> Char
showMaybe Nothing = ' '
showMaybe (Just a) = toChar a

A good trick to figure out type related errors is to remove the type signature and ask
GHCI what type it infers (assuming it is able to). So if you remove the signature all together

showMaybe Nothing = ' '
showMaybe (Just a) = toChar a

and then start up GHCI, it will give you the result

:~$ ghci scratch.hs 
GHCi, version 7.6.1: http://www.haskell.org/ghc/  :? for help
Loading package ghc-prim ... linking ... done.
Loading package integer-gmp ... linking ... done.
Loading package base ... linking ... done.
[1 of 1] Compiling Main             ( scratch.hs, interpreted )
Ok, modules loaded: Main.
*Main> :t showMaybe 
showMaybe :: ToChar a => Maybe a -> Char
*Main>