Question

I’m trying to create a query with dynamic columns, based on data from three tables.

This is the database structure:

STUDENT

• studentID int,
• studentNumber int,
• studentName nvarchar(100).

EXAM:

• examID int,
• examName varchar(100),
• examenDate datetime,

EXAM_REGISTRATION:

• studentID int,
• examID int,

A record is added to the EXAM_REGISTRATION table when a student has registered for an exam.

What I’m trying to get is a list of all the exams and all the students in a pivot table to see which students have registered for which exams, like this:

Quite frankly I don’t know where to start.

I can query everything individually and put it all together but how can I combine it into one query?

I’ve been researching pivot tables, but every example seems to query only from one table and uses numbers and functions like MIN, AVG etc.

Can someone help me along?

Answer 1

ok lets go

some data to play with

create table #student
(studentID int, studentNumber int, studentName nvarchar(100))
create table #exam 
(examID int, examName nvarchar(100), examDate datetime)
create table #examReg
(studentID int, examID int)

insert into #student
values (1, 787878, 'pierwszy')
,(2, 89898, 'drugi')
,(3, 343434, 'trzeci')
,(4, 121212, 'czwarty')

insert into #exam
values (1, 'exPierwszy', GETDATE())
,(2, 'exDrugi', GETDATE())
,(3, 'exTrzeci', GETDATE())

insert into #examReg
values (1,2),(1,3)
, (2,2),(2,3)
,(3,1),(3,2)
,(4,1),(4,2),(4,3)

and now the main part, and explanation

first of all you have to get pivot query

select examName, examDate , min([1])  , min([2]), min([3]) ,min([4])--studentID as studentID, examDate --,studentNumber
from 
(select a.studentID , studentNumber, examDate, examName
from #student a 
join #examReg b on a.studentID = b.studentID
join #exam c on c.examID = b.examID ) as m
pivot
(min(studentNumber) FOR studentID in ([1],[2],[3],[4])) as t
group by examName, examDate

as you have it , just change it select statement and studentID list in pivot declaration, you have to generate those parts dynamicly , so we just copy previously written query and replace columns with our token

    declare @sqlTemplate nvarchar(max) = 
    'select examName, examDate @@sqlColumnList@@
    from 
    (select a.studentID , studentNumber, examDate, examName
    from #student a 
    join #examReg b on a.studentID = b.studentID
    join #exam c on c.examID = b.examID ) as m
    pivot
    (min(studentNumber) FOR studentID in (@@sqlStudentIDList@@)) as t
    group by examName, examDate
'

after that you generate column list and studentID list by concatenting strings in tsql

declare @sqlColumnList nvarchar(max) = ''
select @sqlColumnList += ',min([' + cast(studentID as nvarchar(10)) + ']) as [' + studentName +'(' + cast(studentNumber as nvarchar(10)) + ')]'
from #student
declare @sqlStudentIDList nvarchar(max) = ''
select @sqlStudentIDList += '[' + CAST(studentID as nvarchar(10)) + '],'
from #student

set @sqlStudentIDList = SUBSTRING(@sqlStudentIDList, 0, LEN(@sqlStudentIDList))
select @sqlStudentIDList

once you have it , all you have to do is to replace tokens in previous template

set @sqlTemplate = REPLACE(@sqlTemplate, '@@sqlColumnList@@', @sqlColumnList)
set @sqlTemplate = REPLACE(@sqlTemplate, '@@sqlStudentIDList@@', @sqlStudentIDList)


select @sqlTemplate

exec sp_executesql @sqlTemplate

and thats it
if you want to read more about pivot go for msdn
if you want to read about dynamic go for this link

edit: to adjust the query for the question from comment you would have to change @sqlColumnList like that

select @sqlColumnList += ',min(' + QUOTENAME(studentID)  + ') as Student' + CAST(studentID as nvarchar(10))  + '_REG,
'''+ studentName + ''' as Student' + cast(studentID as nvarchar(10)) + '_NAME,
'+ cast(studentID as nvarchar(10)) + ' as Student' + cast(studentID as nvarchar(10)) + '_ID'
from #student