Question

I’m trying to do a find-and-replace algorithm across a huge batch of .doc files (roughly 200 files).

I need to find and replace about 40 strings. I’ll need to perform such operations regularly, so I feel it would be a very good case in which to create a script.

1. Is it possible to do this via word?
2. If not, is it possible to do this with a .batch file?
3. If not, where should I get started?

Answer 1

The only non-trivial bit is the replace, but you can record & modify that

Sub Foo()
'path 
Const PATH As String = "C:\xxx\"
Dim doc As Word.Document
Dim fn As String: fn = Dir$(PATH & "*.doc")
With Application
    'loop matching files
    Do While Len(fn)
        'open
        Set doc = .Documents.Open(PATH & fn)
        'replace text
        replaceInDoc doc, "OLD TEXT", "NEW TEXT"
        replaceInDoc doc, "MORE OLD TEXT", "MORE NEW TEXT"
        'save, close
        doc.Save
        doc.Close
        'get next file
        fn = Dir$()
    Loop
End With
End Sub

Sub replaceInDoc(doc As Word.Document, find As String, replaceWith As String)
'do the replace
With doc.Content.find
    .Text = find
    .Replacement.Text = replaceWith
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute replace:=wdReplaceAll
End With
End Sub

Obviously test this on a copy.