Question

Im trying to emulate a TCP Server on the same PC where the app is running.
I dont know if it can be done in Perl because im not very experienced.

With the code bellow the first reply is working but i dont know how to implement the second.

#!/usr/bin/perl -w

use IO::Socket::INET;
use strict;


my $socket = IO::Socket::INET->new('LocalPort' => '3000',
                   'Proto' => 'tcp',
                   'Listen' => SOMAXCONN)
    or die "Can't create socket ($!)\n";
print "Server listening\n";
while (my $client = $socket->accept) {
    my $name = gethostbyaddr($client->peeraddr, AF_INET);
    my $port = $client->peerport;
    while (<$client>) {
    print "$_";
    print $client "RESPONSE1";
    }
    close $client
    or die "Can't close ($!)\n";
}
die "Can't accept socket ($!)\n";

EDIT: Thank you guys for the imput, i ended up with php done it and its working, yay!

Answer 1

Use Net::Server for the connection, and a variable in the sub to keep the current state ($state in this code); something like this:

package MyServer;
use base qw/Net::Server/;
use strict;
use warnings;

sub process_request {
  my $self = shift;
  my $state = 0;
  while (<STDIN>) {
    s/\r?\n$//; # like chomp but for crlf too
    if ($state == 0 and $_ eq 'data1') {
      print "> okay1\n";
      $state++;
    } elsif ($state == 1 and $_ eq 'data2') {
      print "> okay2\n";
      $state++;
    } else {
      last if $state == 2;
      $state = 0;
    }
  }
}

my $port = shift || 3000;
MyServer->run( port => $port );

The example in the Net::Server POD suggests using an alarm to timeout connections, which might be appropriate here. The code above does the following:

$ nc localhost 3000
data1
> okay1
data2
> okay2
data3
$

And if you need to move to a forking / preforking / non-blocking / co-routine driven system, there’s a Net::Server personality for that.