Home/ Questions/Q 7508193
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-05-29T22:38:15+00:00

I’m trying to figure this out and I just cannot get it to work,

  • 0

I’m trying to figure this out and I just cannot get it to work, I’m stuck please help.

I have a .txt file that will look something like this

Example:

GA117.50.0117.50.0117.50.0IL16.08.08.00.016.00.0IN284.09.4274.60.0284.00.0KY137.60.0137.60.0137.60.0TN170.30.0170.30.0170.30.0US725.417.4708.00.0725.40.0TOTAL725.417.4708.00.0725.40.0

What I’m trying to do in classic-asp is to get the letters/word in a dim (and add a str before the letters/word) and the numbers as the value for that dim but only to the first period and 1 more number to the right after the period and then continue to the next letter/word.

so the final outcome would look something like this:

dim strGA
dim strIL
dim strIN
dim strKY
dim strTN
dim strUS
dim strTOTAL

strGA=117.5
strIL=16.0
strIN=284.0
strKY=137.6
strTN=170.3
strUS=725.4
strTOTAL=725.4

Thank you so much for any help with this problem/question.

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    Consider the following example.
    May need to change the pattern according to the variable names.

    Dim strTest
    strTest = "GA117.50.0117.50.0117.50.0IL16.08.08.00.016.00.0IN284.09.4274.60.0284.00.0KY137.60.0137.60.0137.60.0TN170.30.0170.30.0170.30.0US725.417.4708.00.0725.40.0TOTAL725.417.4708.00.0725.40.0"
Dim re
Set re = New RegExp
    re.IgnoreCase = True
    re.Global = True
    re.Pattern = "([a-z]+)(\d+\.\d)"

Dim collMatches
Set collMatches = re.Execute(strTest)
Dim iMatch, strDims, strAssocs
For Each iMatch In collMatches
    strDims = strDims & "Dim str" & iMatch.SubMatches(0) & vbCrLf
    strAssocs = strAssocs & "str" & iMatch.SubMatches(0) & " = " & iMatch.SubMatches(1) & vbCrLf
Next

Dim strExec
strExec = strDims & vbCrLf & strAssocs

'Dump
Response.Write "Dump:<hr /><pre>" & strExec & "<pre>"

ExecuteGlobal strExec 'Execute the code

'Test
With Response
    .Write "Executed:<hr />"
    .Write "strGA: " & strGA & "<br />"
    .Write "strIL: " & strIL & "<br />"
    .Write "strIN: " & strIN & "<br />"
    .Write "strKY: " & strKY & "<br />"
    .Write "strTN: " & strTN & "<br />"
    .Write "strUS: " & strUS & "<br />"
    .Write "strTOTAL:" & strTOTAL & "<br />"
End With
    • 0