Question

I’m trying to group data from a table. The table was built off a pivot table, with values returned equaling 1 if the employee had worked on a project or not.

I tried Hlookup, vlookup…can’t figure it out.

The “1” value from the table means that the person worked on that particular project.
I need a formula to say, If L.Bish=”1″, then return all names that also equal “1”

The long way would be to filter table values under each person for value “1” to find whether or not other team members have worked with that person.

I would then need to apply this formula to all other team members to see who has and hasn’t worked together on a project.

Any help or direction would be great

As you can see, Bish has worked with the following:
Carl
Good
Etc.

Table is below:

Answer 1

I assume you have employees and projects in rows and columns or vice-versa. If you were to “unpivot” your table, you’d be able to put it back in a pivot and do your groupings the way you want.

Check out my Table2DB add-in here.

In your case, you could simply run the macro below and create a pivot based on your new sheet

Sub UnPivot()
Dim lLastCol As Long, lLastRow As Long
Dim rgCell As Range, shtOrg As Worksheet, shtDest As Worksheet
Dim lRowDest As Long

'turn off updates to speed up code execution
With Application
    .ScreenUpdating = False
    .EnableEvents = False
    .Calculation = xlCalculationManual
End With

Set shtOrg = ActiveSheet

lLastRow = Cells(Rows.Count, 1).End(xlUp).Row
lLastCol = Cells(48, Columns.Count).End(xlToLeft).Column

Set shtDest = Sheets.Add
lRowDest = 2

shtDest.Cells(1, 1) = "Project"
shtDest.Cells(1, 2) = "Employee"

With shtOrg
    For Each rgCell In .Range(.Cells(49, 2), .Cells(lLastRow, lLastCol)).SpecialCells(xlCellTypeConstants)

        If rgCell.Value = 1 Then
            shtDest.Cells(lRowDest, 1) = .Cells(rgCell.Row, 1)
            shtDest.Cells(lRowDest, 2) = .Cells(48, rgCell.Column)
            lRowDest = lRowDest + 1
        End If

    Next rgCell
End With

With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = xlCalculationAutomatic
End With

End Sub

To get the ones who didn’t work together, build a table as shown below and use formula:
=IF(COUNTIFS(OFFSET($A$49:$A$78,0,MATCH($A2,$48:$48,0)-1,,),1,OFFSET($A$49:$A$78,0,MATCH(B$1,$48:$48,0)-1,,),1)>0,”Did”,”Didn’t”) & ” Work together”