Question

I’m trying to implement a trigger to search values on a table, and, if it checks the condtion then insert in another table. The Trigger looks like this:

TRIGGER DISTANCIA
AFTER INSERT ON OBSERVACION FOR EACH ROW
DECLARE
importe_multa NUMBER (3,0);
BEGIN
 FOR ROW IN (SELECT fecha_foto, hora_foto, pto_km_radar, sentido_radar, carretera_foto FROM OBSERVACION) LOOP
    IF((ROW.fecha_foto = :NEW.fecha_foto)
    AND
    (ROW.carretera_foto= :NEW.carretera_foto)
    AND
    (ROW.pto_km_radar=:NEW.pto_km_radar)
    AND
    (ROW.sentido_radar=:NEW.sentido_radar))
    THEN

    IF(ROW.hora_foto<:NEW.hora_foto-3,6/86400)
    THEN
    importe_multa:= (:NEW.hora_foto - ROW.hora_foto - 3,6/86400)*100;
    END IF;
    IF(:NEW.hora_foto < ROW.hora_foto-3,6/86400)
    THEN
    importe_multa:= (ROW.hora_foto - :NEW.hora_foto - 3,6/86400)*100;
    END IF;

   IF(importe_multa IS NOT NULL)
   THEN
     --Introducimos el valor en el campo.
     INSERT INTO SANCION(importe, fecha_foto, hora_foto, coche, tipo)
     VALUES
     (importe_multa, :NEW.fecha_foto, :NEW.hora_foto, :NEW.coche, '2');
     END IF;
    END IF;
END LOOP;
END;

When I try to compile the SQLDeveloper software throws this error:

ORA-01008: Not all variables bound.

Am I referencing the variables in OBSERVACION right?

Answer 1

1) A row-level trigger on OBSERVACION cannot query then OBSERVACION table. If you do, you’ll get a mutating trigger error. So the approach is fundamentally problematic.

2) I would expect that you’re getting the compilation error because you need to represent decimal numbers using the decimal point as the separator, not the comma. The comma is used to separate parameters to a function.

3) If you really want to implement this sort of logic in a trigger rather than putting it in a procedure where it really belongs, you’ll need to work around the mutating trigger error with a series of triggers. This is going to make your code substantially more complex, harder to follow, and harder to debug. But it would allow you to do this using only triggers.

CREATE OR REPLACE PACKAGE pkg_new_rows
AS
  TYPE typ_new_row_array 
    IS TABLE OF rowid;
  g_new_rows typ_new_row_array;
END;

CREATE OR REPLACE TRIGGER trg_before_statement
  BEFORE INSERT ON OBSERVACION
DECLARE
BEGIN
  pkg_new_rows.g_new_rows := new pkg_new_rows.typ_new_row_array();
END;

CREATE OR REPLACE TRIGGER trg_before_row
  BEFORE INSERT ON observacion
  FOR EACH ROW
DECLARE
BEGIN
  pkg_new_rows.g_new_rows.extend;
  pkg_new_rows.g_new_rows( pkg_new_rows.g_new_rows.count ) := :new.rowid;
END;

CREATE OR REPLACE TRIGGER trg_after_statement
  AFTER INSERT ON observacion
DECLARE 
  l_row observacion%rowtype;
BEGIN
  FOR i IN 1 .. pkg_new_rows.g_new_rows.count
  LOOP
    SELECT *
      INTO l_row
      FROM observacion
     WHERE rowid := pkg_new_rows.g_new_rows(i);

   <<implement your logic by querying the other rows of the OBSERVACION table
     and comparing that to the data in the l_row record>>
  END LOOP;
END;