Question

I’m trying to parse strings with fnparse and I need to act on a character differently if it is at the end of a word. For this I have rules thus:

(def a-or-s
  (rep* (alt (lit \a) (lit \s))))

(def ends-with-s
  (conc a-or-s (lit \s)))

I try to match the string “aas”. This however doesn’t parse because the rep* is greedy and swallows up the last character of the word and the conc rule doesn’t work. How can I get round this and match these constructions properly?

Answer 1

For that you’ll need to use the followed-by rule, basically you want to repeatedly match ‘a’ or ‘s’ but without consuming the last token. Here’s the code to do that:

(def a-or-s
  (lit-alt-seq "as")) ;; same as (alt (lit \a) (lit \s))

(def ends-with-s 
  (conc 
   (rep* (conc a-or-s (followed-by a-or-s))) 
   (lit \s)))

We can refactor that code to create a non-greedy version of rep* like this:

(defn rep*? [subrule] 
  (rep* (conc subrule (followed-by subrule))))

Then use it instead of rep* and your original code should work as expected. After trying it though…

user> (rule-match (conc (rep*? a-or-s) (lit \s)) identity #(identity %2) {:remainder "aaaaaaaasss"})
([(\a \a) (\a \a) (\a \a) (\a \a) (\a \a) (\a \a) (\a \a) (\a \s) (\s \s) (\s \s)] \s)

…you might ask “what’s happening to the output?”, well rep*? is giving us pairs of tokens because that’s what we asked for. This can fixed using invisi-conc instead of conc:

(defn rep*? [subrule] 
  (rep* (invisi-conc subrule (followed-by subrule))))

user> (rule-match (conc (rep*? a-or-s) (lit \s)) identity #(identity %2) {:remainder "aaaaaaaasss"})
([\a \a \a \a \a \a \a \a \s \s] \s)