Question

I’m trying to replace instances created by dragging and dropping into a MovieClip through Flash’s IDE with actual classes so I can add them to a game loop and have them as actual entities. In other words, I’m trying to create a streamlined way to allow developers to visually add their entities to a platforming engine I’m working on.

This is my third attempt at it and I’m completely stuck.

The code below loops through a movieclip that contains an exported symbol with a class linked to it named MyEntity. However, it loses its extension to BaseClass and thus doesn’t move when compiled.

It inherits: MovieClip > BaseClass > MyEntity. However when compiled with the IDE it ignores BaseClass and just does MovieClip > MyEntity.

My code is designed to find and store the position of MyEntity, remove it from the container movieclip, add a brand new instance of it (with the base being proper) then set that new instance to the same position of the original.

for ( var i:int = 0; i < LayerInIDE.numChildren; i++ )
{
    // first we want to get all the display objects in the layer
    // these are objects that were placed from within the Flash IDE (ie. dragged and dropped into the MovieClip
    var original:DisplayObject = LayerInIDE.getChildAt( i );            

    // we want to get the class of the display object so we can recreate it as a specific entity class that it 
    var originalName:String = getQualifiedClassName( original );
    var originalClass:Class = getDefinitionByName( originalName ) as Class;

    // debug trace, see output below
    trace( originalName, originalClass, originalClass is BaseClass );

    // filter out movieclips
    if ( originalClass != MovieClip )
    {
        // remove the original
        LayerInIDE.removeChild( original );

        // recreate the class with the correct extension
        var newEnt = originalClass();
            newEnt.x = original.x; newEnt.y = original.y;
        LayerInIDE.addChild( newEnt );
    }
}

This does not work.

It outputs Game.entities::MyEntity [class MyEntity] false. MyEntity is a proper class and DOES extend from BaseClass. However, the issue is the IDE weirdly removes the reference to the base class – as if MyEntity never had a base class. I cannot seem to recreate it as getting the reference to the class also returns that MyEntity never had a BaseClass. However, if I type in var newEnt = MyEntity(); instead of getting the class name through getDefinitionByName it works normally and extends from BaseClass.

I need it to extend from BaseClass as that is the main class all entities in my game engine require to use.

Any ideas? Or is there a better way?

Answer 1

After much tinkering and generally breaking Flash, I got the solution to my problem. Thanks to Stephen Braitsch‘s help for getting me in the right direction.

Okay, so this solution is a little complicated (and hacky) but it gets around the issues I was previously discussing.

First you’ll need the main function that scans through all the display objects in a specific movieclip. I’ve named mine LayerInIDE.

There’s two functions needed. ReplaceEnts and Recreate. ReplaceEnts scans through all the objects and determines if they extend from BaseClass. If they do, it goes ahead and throws them through Recreate. Recreate takes the original class and position and recreates the class allowing us to access the asset during runtime properly.

import Game.entities.MyEntity;
import Game.entities.BaseClass;
import Game.entities.Layer;

var LayerInIDE:Layer = new Layer();
stage.addChild( LayerInIDE );

ReplaceEnts( LayerInIDE );

function ReplaceEnts( layer:Layer ):void
{
    for ( var i:int = 0; i < layer.numChildren; i++ )
    {
        // Get the display object.
        var original:DisplayObject = layer.getChildAt( i );

        // Make sure we're only doing this to objects that extend from BaseClass
        if ( original is BaseClass )
        {
            // Get the original class
            var originalName:String = getQualifiedClassName( original );
            var originalClass:Class = getDefinitionByName( originalName ) as Class;
            // Remove the original
            layer.removeChild( original );

            // Recreate it with the original class
            // Make sure we keep the original position and rotation.
            var bc = Recreate( originalClass, original.x, original.y, original.rotation );
            layer.addChild( bc );

            // Test functions
            trace( bc ); // outputs: [object MyEntity]
            bc.TestFunc(); // outputs: test
            bc.BaseTest(); // outputs: base
        }
    }
}

// This is the core function that does all the work.
// It recreates the entity with the proper class and sets it to its original position.
function Recreate( entClass:Class, iPosX:int = 0, iPosY:int = 0, iRot:int = 0 ):BaseClass
{
    var newEnt:BaseClass = new entClass();
    newEnt.x = iPosX; newEnt.y = iPosY;
    newEnt.rotation = iRot;

    return newEnt;
}

Then the BaseClass contains:

package Game.entities
{
    import flash.display.MovieClip;

    public class BaseClass extends MovieClip
    {
        // The example function as mentioned above in the ReplaceEnts function.
        public function BaseTest():void
        {
            trace( "base" );
        }
    }
}

Once that is all set, we’ll need to also make the MyEntity class:

package Game.entities
{
    public class MyEntity extends BaseClass
    {
        // The example function as mentioned above in the ReplaceEnts function.
        public function TestFunc():void
        {
            trace( "test" );
        }
    }
}

Just a final note, Games.entities.Layer is just a simple MovieClip. I only created my own class for it for organization purposes in this.

The solution here is simple. When a user drags an object that extends from BaseClass into a layer, the function runs on start up and replaces the asset with the proper class and allows for an entity manager to take over and handle the asset appropriately. It allows for what I wanted to achieve, an IDE-powered level editor that automatically does all the work placing the entities where you want them.

Thanks for all the help guys.