Question

I’m trying to send a URL to chrome for viewing flash, quit Safari in the meanwhile so it’s not using up memory, and then as soon as I quit Chrome, go back to Safari. It’s not predictably going back to Safari after I quit Chrome, so I need help with the repeat loop. I want to run this as a service. Thanks!

property theURL : ""

on run {input, parameters}

tell application "Google Chrome"
    activate
end tell

tell application "Safari"
    activate
end tell

tell application "System Events"
    keystroke "j" using {command down} -- Highlight the URL field.
    keystroke "c" using {command down}
    keystroke "w" using {command down}
end tell

delay 0.1

tell application "Safari"
    quit
end tell

tell application "Google Chrome"
    if (count of (every window where visible is true)) is greater than 0 then
        tell front window
            make new tab
        end tell
    else
        make new window
    end if
    set URL of active tab of front window to the clipboard
    activate
end tell

repeat
    if application "Google Chrome" is not running then exit repeat
    delay 5
end repeat

tell application "Safari"
    activate
end tell

return input
 end run

Update! Here’s the working script:

 property theURL : ""

 on run

tell application "Safari"
    activate
    set theURL to URL of document 1
    quit
end tell


tell application "Google Chrome"
    activate
    if (count of (every window where visible is true)) is greater than 0 then
        tell front window
            make new tab
        end tell
    else
        make new window
    end if
    set URL of active tab of window 1 to theURL
    activate tab 1
end tell

repeat
    tell application "System Events"
    if "Google Chrome" is not in (name of application processes) then exit repeat
    end tell
    delay 5
end repeat

tell application "Safari"
    activate
end tell


end run

Answer 1

You could try this…

repeat
    tell application "System Events"
        if "Google Chrome" is not in (name of application processes) then exit repeat
    end tell
    delay 5
end repeat

Also I always avoid using keystrokes and other gui scripting stuff if I can avoid it. They’re not 100% reliable. As such I suggest you transfer the url like this…

tell application "Safari" to set theURL to URL of document 1

and…

tell application "Google Chrome" to set URL of active tab of window 1 to theURL