Question

I’m trying to transform the following XML..

<?xml version="1.0" encoding="utf-16"?><Member TextRank="unknown" FullName="My Name" ..etc.. />

Into something like the following,

<div class="member">
    <span class="label">
        Text Rank (note: i want to override the labels in the xslt)
    </div>
    <span class="value">
        unknown
    </span>
    <span class="label">
        Full Name
    </div>
    <span class="value">
        My Name
    </span>
    ..etc..
</div>

How if possible could I do this using xslt?

Answer 1

Here’s a different approach, that does away for the need for the xsl:choose element. Instead, you could take advantage of the matching templates to have specific templates for the cases of attributes who names you want to override, and a generic template for other case.

To avoid repetition of code, you could also make the generic template a named template, with a parameter to override the name

<xsl:template match="@*" name="attribute">
   <xsl:param name="label" select="local-name()" />

So, the default for most attributes would be to use the attribute name, but the specific template for @FullName could then call this with a different name.

<xsl:template match="@FullName">
   <xsl:call-template name="attribute">
      <xsl:with-param name="label" select="'Full Name'" />
   </xsl:call-template>
</xsl:template>

Here is the full XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes"/>

   <xsl:template match="*">
      <div class="{local-name()}">
         <div> Title: </div>
         <xsl:apply-templates select="@*"/>
      </div>
   </xsl:template>

   <xsl:template match="@FullName">
      <xsl:call-template name="attribute">
         <xsl:with-param name="label" select="'Full Name'" />
      </xsl:call-template>
   </xsl:template>

   <xsl:template match="@*" name="attribute">
      <xsl:param name="label" select="local-name()" />
      <span class="label">
         <xsl:value-of select="concat($label, ' : ')"/>
      </span>
      <span class="value">
         <xsl:value-of select="."/>
      </span>
      <br/>
   </xsl:template>
</xsl:stylesheet>

When applied to the following XML:

<Member TextRank="unknown" ID="12" FullName="My Name" Dob="01/01/1970" />

The following is output:

<div class="Member">
   <div> Title: </div>
   <span class="label">TextRank : </span>
   <span class="value">unknown</span>
   <br>
   <span class="label">ID : </span>
   <span class="value">12</span>
   <br>
   <span class="label">Full Name : </span>
   <span class="value">My Name</span>
   <br>
   <span class="label">Dob : </span>
   <span class="value">01/01/1970</span>
   <br>
</div>