Home/ Questions/Q 8070071
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-05T13:16:36+00:00

I’m trying to use HTTP::Proxy to server 403 error for some specific domain. I

  • 0

I’m trying to use HTTP::Proxy to server 403 error for some specific domain. I already managed to modify headers, but the proxy continue to serve the original page.

Here is the code I’m using:

package Filters::Filter403;

use strict;
use warnings;
use HTTP::Proxy::HeaderFilter::simple;
use HTTP::Proxy::BodyFilter::simple;

our $header = HTTP::Proxy::HeaderFilter::simple->new (
    sub {
        $_[2]->code( 403 );
        $_[2]->message ( 'Forbidden' );
    }
);

our $body = HTTP::Proxy::BodyFilter::simple->new (
    sub {       
        $_[1] = \<<'HTML';
<!DOCTYPE html>
<html><head><title>403 Forbidden</title><style type="text/css">
body { padding: 40pt; }
body, h1, h2, p { color: #333; font-family: Arial, sans-serif; margin: 0; }
div { width: 200px; background: #eee; padding: 2em; }
</style></head><body><div><h1>403</h1><h2>Forbidden</h2></div></body></html>
HTML
    }
);

1;

Here is the code from the main script where I’m calling this two filters, so you can have a better look:

use HTTP::Proxy qw(:log);
use Getopt::Long;

use FindBin qw($Bin);
use lib $Bin;

use Filters;
use HTTP::Proxy::BodyFilter::complete;

my $port = 3128;
my $fail_at;
my $outputfile = '/var/log/cvmfs-test/webproxy.output';
my $errorfile = '/var/log/cvmfs-test/webproxy.error';

my $ret = GetOptions ( "port=i" => \$port,
                       "fail=s" => \$fail_at );

my @fail_at = split(/,/, $fail_at);

# Opening file for log
open (LOG, '>>', $outputfile);

my $proxy = HTTP::Proxy->new;
$proxy->port( $port );
$proxy->logfh( *LOG );
$proxy->logmask( ALL );

if ($fail_at[0] ne 'all') {
    foreach my $url (@fail_at) {
        $proxy->push_filter(
            host => $url,
            response => HTTP::Proxy::BodyFilter::complete->new,
            response => $Filters::Filter403::header,
            response => $Filters::Filter403::body
        );
    }
}
else {
    $proxy->push_filter (
        response => HTTP::Proxy::BodyFilter::complete->new(),
        response => $Filters::Filter403::header,
        response => $Filters::Filter403::body
    );
}

my $pid = fork();

# Command for the forked process
if ( defined($pid) and $pid == 0 ) {
    open (my $errfh, '>', $errorfile);
    STDOUT->fdopen( \*$errfh, 'w' ) || die "Couldn't set STDERR to $errorfile: $!\n";
    $proxy->start;
}

# Command for the main script
unless ($pid == 0) {
    print "Proxy HTTP started on port $port with PID $pid.\n";
    print "You can read its output in $outputfile.\n";
}

exit 0;

Can you please help me?
I tried Daxim solution and I also tried to use $ { $_[1] } as documentation seems to suggest, but it didn’t works.

Thank you very much.

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    I have found a solution.
    The problem is that every filter after HTTP::Proxy::BodyFilter::complete->new is executed with empty data. I found that loading an heavy page, my code were added multiple times.

    Here is the working filter:

    our $body = HTTP::Proxy::BodyFilter::simple->new (
    sub {
        my ( $self, $dataref, $message, $protocol, $buffer ) = @_;
        unless (defined ($buffer)){
            my $html = 
                    '<!DOCTYPE html>'.
                    '<html><head><title>403 Forbidden</title><style type="text/css">'.
                    'body { padding: 40pt; }'.
                    'body, h1, h2, p { color: #333; font-family: Arial, sans-serif; margin: 0; }'.
                    'div { width: 200px; background: #eee; padding: 2em; }'.
                    '</style></head><body><div><h1>403</h1><h2>Forbidden</h2></div></body></html>';

            $$dataref = $html;
        }
    }
);

    This way, the filter doesn’t do anything unless $buffer is undef, i.e. when the whole response was received.

    • 0