Question

Im trying to use printf in my assembley code in model large, and i get a fixup overflow, what do i need to change in this code to make it work?

.MODEL LARGE
.STACK 100h
.DATA
int     DW "%d"
.CODE
.386

extrn   _printf:far
PUBLIC _stack_protection
_stack_protection PROC FAR
push    bp          
mov bp,sp           
push    es
mov     ax,10
push    ax
push    word ptr int
call    _printf
add sp,4
pop es  
pop bp          
ret 
_stack_protection ENDP
    END

Answer 1

You need to change this:

int     DW "%d"

to this:

_int     DB "%d",0

Because printf() expects normal, NUL-terminated C strings, because C strings consist of bytes, not words and because int is likely a reserved word (at least it is in TASM).

You also need to change this:

push    word ptr int
...
add sp,4

to this:

push    seg _int
push    offset _int
...
add sp,6

Because in the large memory model all pointers are far, that is, consist of a segment and an offset.

So, this is what I end up with…

Asm file:

; file: larg.asm
; how to assemble: tasm.exe /ml larg.asm
.MODEL LARGE

;.STACK 100h ; unnecessary and too small anyway,
; let the C compiler take care of it

DATA segment word public 'DATA' ; make sure class='DATA' (default)
;int     DW "%d" ; 'int' is a reserved word,
; C strings must consist of bytes/chars and end with byte 0
_int    DB "%d", 0
DATA ends

extrn   _printf:far ; for some reason this must be
; outside of the code segment

CODE segment byte public 'CODE' USE16 ; make sure it's
; 16-bit code, class='CODE' (default)
assume cs:CODE
.386

PUBLIC _stack_protection
_stack_protection PROC FAR
push    bp
mov     bp,sp
push    es
mov     ax,10
push    ax
;push    word ptr int ; must be the far address of '_int'
; because in the 'large' memory model all pointers are 'far'
push    seg _int
push    offset _int
call    _printf
;add sp,4 ; must account for the far address size on stack
add     sp,6
pop     es
pop     bp
ret
_stack_protection ENDP
CODE ends

    END

C file:

// file: large.c
// how to compile: tcc.exe -mlarge large.c larg.obj

#include <stdio.h>

extern void stack_protection(void);

int main(void)
{
  stack_protection();
  printf("\n");
  return 0;
}

I then compile the program (with Turbo C++ 1.01 and TASM 3.2):

tasm.exe /ml larg.asm
tcc.exe -mlarge large.c larg.obj

And run it:

c:\large.exe
10