Question

I’m trying to use the type Boolean for some parameter.

<AttributeUsage(AttributeTargets.Method, Inherited:=True, AllowMultiple:=False)>
Public Class MyAttribute
             Inherits Attribute
  Property MyCondition As Boolean
End Class

I’m facing the problem that, in my object MyAttribute, I’m not able to say if the boolean property has the value False:

• because of the presence of the parameter (e: MyCondition:=false)

or,

• because no parameter was passed and my property has the value False because of the initialization of my object.

I though about using a property Nullable(Of Boolean) instead, but this doesn’t seem to be allowed?

Property MyCondition As Nullable(of Boolean)

Error message “Property or field ‘MyCondition’ does not have a valid attribute type.”

Is there a walk-around this situation? Is the only workable parameter type is String (that is null on instantiation) ?

Answer 1

I believe that you can only use simple data types that can be represented as a literal constant in code (e.g. 100, True, “Test”). That is probably why Nullable(Of Boolean) is not working for you. You can, however, accomplish what you are trying to do by creating actual property handlers:

<AttributeUsage(AttributeTargets.Method, Inherited:=True, AllowMultiple:=False)>
Public Class MyAttribute
    Inherits Attribute

    Public Property MyCondition As Boolean
        Get
            Return _myCondition
        End Get
        Set(ByVal value As Boolean)
            _myCondition = value
            _explicitlySet = True
        End Set
    End Property
    Private _myCondition As Boolean = False

    Public ReadOnly Property ExplicitlySet As Boolean
        Get
            Return _explicitlySet
        End Get
    End Property
    Private _explicitlySet As Boolean = False
End Class

Alternatively, you could make it a read-only nullable property and use a constructor to set it:

<AttributeUsage(AttributeTargets.Method, Inherited:=True, AllowMultiple:=False)>
Public Class MyAttribute
    Inherits Attribute

    Public Sub New()
    End Sub

    Public Sub New(myCondition As Boolean)
        _myCondition = myCondition
    End Sub

    Public ReadOnly Property MyCondition As Nullable(Of Boolean)
        Get
            Return _myCondition
        End Get
    End Property
    Private _myCondition As Nullable(Of Boolean)
End Class