Question

I’m trying to write a batch file that is basically used for copying destinations. Now, I want to make it to where other people can use it without having to go in and edit the directories and destinations. Is there a way for me to write the batch file to where it prompts, asking for the directory the user would like to copy, and to ask for the drive that the user would like to copy it to?

This is what I’ve been using for a while now.

@echo off
:: variable
set backupdir="Destination"
set backupcmd=xcopy /e /h /f /y /v /c /i /r /g /k /d
echo.
echo +++ Backing Up Data +++
echo.
echo.
%backupcmd% "Directory\*.*" "%backupdir%\Data"
timeout /t 2
cls
echo Backup Complete
echo.
echo.
timeout /t 2
cls
echo.
echo +++ Now taking hidden and system attributes off of folders +++
echo.
echo.
echo.
attrib -s -h "Destination\Data"
echo.
echo.
timeout /t 3

And is there any way that I can improve this with using xcopy?

Answer 1

You could use:

SET /P variable=[promptString]

From the docs:

The /P switch allows you to set the value of a variable to a line of input entered by the user. Displays the specified promptString before reading the line of input. The promptString can be empty.

You use it like:

set /p backupdir=Enter Destination Directory: 

And:

set /p sourcedir=Enter Source Directory: 

Then change your copy command to:

%backupcmd% "%sourcedir%\*.*" "%backupdir%\Data"

And don’t forget your attrib command (which should have already been using %backupdir%):

attrib -s -h "%backupdir%\Data"

As an alternative, consider allowing optional command line arguments:

dobackup Destination BackupDir

Implemented with these changes:

if "%1" == "" (
    set /p backupdir=Enter Destination Directory: 
) else (
    set backupdir=%~1
)

if "%2" == "" (
    set /p sourcedir=Enter Source Directory: 
) else (
    set sourcedir=%~2
)

Finally, adding a SETLOCAL line after @echo off will keep your named variables out of the global environment space.