Question

I’m using a ListCollectionView as an ItemsSource for a WPF DataGrid.

I want the user to be able to add columns to group by, and I’m using the following as the GroupStyle:

<DataGrid.GroupStyle>
    <GroupStyle>
        <GroupStyle.ContainerStyle>
            <Style TargetType="{x:Type GroupItem}">
                <Setter Property="Template">
                    <Setter.Value>
                        <ControlTemplate TargetType="{x:Type GroupItem}">
                            <Expander>
                                <Expander.Header>
                                    <StackPanel Orientation="Horizontal">
                                        <TextBlock Text="Group Name: "/>
                                        <TextBlock Text="{Binding Path=Name}" FontWeight="Bold"/>
                                        <TextBlock Text=" "/>
                                        <TextBlock Text="{Binding Path=ItemCount}" FontStyle="Italic"/>
                                        <TextBlock Text=" Items" FontStyle="Italic"/>
                                    </StackPanel>
                                </Expander.Header>
                                <ItemsPresenter>

                                </ItemsPresenter>
                            </Expander>
                        </ControlTemplate>
                    </Setter.Value>
                </Setter>
            </Style>
        </GroupStyle.ContainerStyle>
    </GroupStyle>
</DataGrid.GroupStyle>

My problem is that when there is more then 1 column in the GroupDescriptions, then group headings are displayed without indentation. Another problem is that I would like the TextBox that has “Group Name:” to bind to the Column name that is grouping that level – So if I’m groupint at that level on column = Gender it would say “Gender: “.

So how can I indent the group heading according to its nesting level in the GroupDescriptions collection, and how can I bind to the Column name?

Answer 1

No one stepped up to this, so with a lot of tinkering, I came up with the following solution. I created a multi value converter, taking the current CollectionViewGroup, the whole ListCollectionView and the DataGrid as parameters.

Public Class GroupLevelConverter
    Implements IMultiValueConverter

    Public Function Convert(values() As Object, targetType As System.Type,
                            parameter As Object, culture As System.Globalization.CultureInfo
                            ) As Object Implements System.Windows.Data.IMultiValueConverter.Convert
        If TypeOf values(0) Is CollectionViewGroup Then
            Dim level As Integer = 0
            Dim parent As CollectionViewGroup = values(0)
            Do While parent IsNot Nothing
                parent = GetParent(values(0))
                values(0) = parent
                If parent IsNot Nothing Then
                    level += 1
                End If
            Loop
            Dim s As String = ""
            For i = 1 To level - 1
                s += "    "
            Next
            Dim lcv As ListCollectionView = DirectCast(values(1), ListCollectionView)
            Dim pgd As System.Windows.Data.PropertyGroupDescription = lcv.GroupDescriptions(level - 1)
            Dim dg As DataGrid = values(2)
            Dim GroupHeader As String = pgd.PropertyName
            For c = 0 To dg.Columns.Count - 1
                If dg.Columns(c).SortMemberPath = GroupHeader Then
                    GroupHeader = dg.Columns(c).Header
                    Exit For
                End If
            Next
            s = s & GroupHeader & ": "
            Return (s)
        End If
        Return ""

    End Function

    Public Function ConvertBack(value As Object, targetTypes() As System.Type, parameter As Object, culture As System.Globalization.CultureInfo) As Object() Implements System.Windows.Data.IMultiValueConverter.ConvertBack
        Throw New NotSupportedException("Not implemented")
    End Function

    Friend Function GetParent(currentViewGroup As CollectionViewGroup) As CollectionViewGroup
        Dim parent As CollectionViewGroup
        Try
            parent = TryCast(currentViewGroup.[GetType]().GetProperty("Parent", System.Reflection.BindingFlags.GetProperty Or
                                                                                                System.Reflection.BindingFlags.Instance Or
                                                                                                System.Reflection.BindingFlags.NonPublic).GetValue(currentViewGroup, Nothing), 
                                                                  CollectionViewGroup)
        Catch ex As Exception
            Return Nothing
        End Try
        Return parent
    End Function
End Class

The CollectionViewGroup is used to find its parent with the GetParent function. This is the non-elegant part of the solution as it relies on capturing an error. The function is called until the error indicates reaching the top group.

ListCollectionView is used to get the sort column, and the DataGrid to get the more friendly Column Header.

HTH someone looking at a similar problem.