Question

I’m using a program see here: Visual Basic Regular Expression Question. I enter letters and the program returns all possible combinations from list. I want change this line of code…

Dim result = fruits.Where(Function(fruit) Not fruit.Except(letters).Any())

If I have this list:

 Dim fruit as List(Of string) from {"apple","orange","pear","banana"}

And I input “p a p l e r” then it would return “apple” and “pear”, but if I enter “a p l e r” then it would return just “pear”. The idea is to return all words, which can be made of entered letters without duplicating any single letter. How to optimize this Linq code?

Answer 1

This could be cleaner, but it works:

Dim fruits As New List(Of String) From { "apple", "orange", "pear", "banana" }
Dim input As String = "a,p,l,e,r"
dim inputLetters = from letter in input.Replace(",", "") group by letter into Group select group.first, Group.Count

dim result = fruits.where(
    function(fruit) 
        dim fruitcounts = from letter in fruit group by letter into Group select group.first,  group.count 
        dim res = from fc in fruitcounts, inputs in inputletters where fc.first = inputs.first andalso fc.count <= inputs.count select fc.first
        return res.count = fruit.count
    end function
    )

edit – I removed some unneeded order by clauses, and simplified the grouping

edit again – after some more thinking, here’s a version that has more lines, but is much clearer and better factored:

Sub Main

    Dim fruits As New List(Of String) From { "apple", "orange", "pear", "banana" }
    Dim input As String = "a,p,l,e,r"

    dim matchingFruits = from fruit in fruits where CanBeMadeFrom(fruit, input)

End Sub

Function StringToFrequencyTable(input as string) as Dictionary(of Char, Integer)

    dim freqTable = from letter in input 
                    group by letter into Group
                    select letter, Group.Count()

    return freqTable.ToDictionary(function(g) g.Letter, function(g) g.Count)

end function

Function CanBeMadeFrom(candidate as string, letters as string) as boolean

    dim inputLetters = StringToFrequencyTable(letters.replace(",", ""))
    dim IsCharInFrequencyTable = function(x) (from entry in inputLetters where entry.Key = x.Key andalso entry.Value >= x.Value).Any()

    return StringToFrequencyTable(candidate).All( IsCharInFrequencyTable )

end function

If I did anything else to this, I would make CanBeMadeFrom and StringToFrequencyTable into extension methods.