Question

I’m using Glorp in VisualWorks and with an Oracle database. Because Oracle does not know the LIMIT command, following query returns all the records of myTable for which the WHERE clause evaluates to true.

q := Glorp.SimpleQuery
       returningManyOf: MyTable
       where: [:each | each name = 'test']
       limit: 10.
q orderBy: [:each | each id descending].
results:= aGlorpSession execute: q.

How would I go to incorporate ROWNUM in this Glorp query?

//edit Generated SQL:

SELECT t1.id, t1.name
 FROM MyTable t1
 WHERE (t1.name= ?) ORDER BY t1.id DESC

Answer 1

On Smalltalk.Glorp.DatabasePlatform I added two empty methods #printPreLimitWrapper:on: and #printPostLimitWrapper:on: which I override in Smalltalk.Glorp.OraclePlatform:

printPreLimitWrapper: anInteger on: aCommand
    aCommand nextPutAll: ' SELECT * FROM ( '

printPostLimitWrapper: anInteger on: aCommand

    aCommand nextPutAll: ' ) WHERE ROWNUM <= '.
    anInteger printOn: aCommand.
    aCommand nextPutAll: ' '.

On Smalltalk.Glorp.SimpleQuery I added:

printPostLimitWrapperOn: aCommand
    self hasLimit ifFalse: [^self].
    self platform printPostLimitWrapper: self limit on: aCommand.

printPreLimitWrapperOn: aCommand
    self hasLimit ifFalse: [^self].
    self platform printPreLimitWrapper: self limit on: aCommand.

And on Smalltalk.Glorp.QuerySelectCommand I altered the following method:

printSQL
    query printPreLimitWrapperOn: self.
    stream nextPutAll: 'SELECT '.
    query printSelectFieldsOn: self.
    self findBoundExpressions.
    query printTablesOn: self.
    query printWhereClauseOn: self.
    query printJoinsOn: self.
    query printOrderingOn: self.
    query printGroupByOn: self.
    query printPostLimitOn: self.
    query printOffsetOn: self.
    query printPostLimitWrapperOn: self.